커뮤니티
수식확인시
2019-04-17 08:54:16
232
글번호 127902
새로작성하고 수식확인시
"선언되지 않은 이름 'HiLoLineigZag'이(가) 사용되었습니다"
라는 설명이 나옵니다. 어떻게 해야 수식이 정확히 완성되는지 알고싶습니다..
답변 1
예스스탁 예스스탁 답변
2019-04-17 11:06:36
안녕하세요
예스스탁입니다.
수식작성시에 작성자가 임의로 만든 함수가 있을수 있습니다.
HiLoLineigZag는 기존제공함수는 아닙니다.
이전문의들 중에 동일이름의 함수가 있어 올려드립니다.
사용자함수로 작성하셔야 합니다.
사용자함수명 : HiLoLineZigZag
반환값형 : 숫자형
Input:Length(NumericSimple),useCLprice(NumericSimple),
oHiZZ[MaxSize1,MaxSize2](NumericArrayRef), // 열번호 1:가격,2:Index,3:sDate,4:sTime
oLoZZ[MaxSize3,MaxSize4](NumericArrayRef),
oTL_NewBit(NumericRef); // 1:NewLine 2:SetEndLine
Var:j(0),jj(0),HH(0),LL(0),최종고가(0),최종저가(0),최종꼭지점(""),처리구분("");
#==========================================#
HH = IFF(useCLprice==1,C,H);
LL = IFF(useCLprice==1,C,L);
If Index == 0 Then {
oHiZZ[1,1] = HH;
oLoZZ[1,1] = LL;
}
Condition1 = Highest(HH,length) == HH and 최종고가 <> HH;
Condition2 = Lowest (LL,length) == LL and 최종저가 <> LL;
처리구분 = "";
If Condition1 and Condition2 Then { // 기간고점과 기간저점 동시 발생
If 최종꼭지점 == "저점" Then {
If oLoZZ[1,1] > LL Then 처리구분 = "저점처리";
Else 처리구분 = "고점처리";
} Else If 최종꼭지점 == "고점" Then {
If oHiZZ[1,1] < HH Then 처리구분 = "고점처리";
Else 처리구분 = "저점처리";
}
} Else If Condition1 Then 처리구분 = "고점처리";
Else If Condition2 Then 처리구분 = "저점처리";
oTL_NewBit = 0;
#==========================================#
If 처리구분 == "고점처리" Then {
최종고가 = HH; // 신규고점을 체크하기 위해 저장
If 최종꼭지점 == "저점" Then {
For j = 10 DownTo 2 {
For jj = 1 To 4 {
oHiZZ[j,jj] = oHiZZ[j-1,jj];
}
}
oHiZZ[1,1] = HH;
oHiZZ[1,2] = Index;
oHiZZ[1,3] = sDate;
oHiZZ[1,4] = sTime;
oTL_NewBit = 1;
} Else If oHiZZ[1,1] < HH Then { // 1번 고점보다 높은 고가 출현
oHiZZ[1,1] = HH;
oHiZZ[1,2] = Index;
oHiZZ[1,3] = sDate;
oHiZZ[1,4] = sTime;
oTL_NewBit = 2;
}
최종꼭지점 = "고점";
}
#==========================================#
If 처리구분 == "저점처리" Then {
최종저가 = LL;
If 최종꼭지점 == "고점" then {
For j = 10 DownTo 2 {
For jj = 1 To 4 {
oLoZZ[j,jj] = oLoZZ[j-1,jj];
}
}
oLoZZ[1,1] = LL;
oLoZZ[1,2] = Index;
oLoZZ[1,3] = sDate;
oLoZZ[1,4] = sTime;
oTL_NewBit = 1;
} Else If oLoZZ[1,1] > LL then {
oLoZZ[1,1] = LL;
oLoZZ[1,2] = Index;
oLoZZ[1,3] = sDate;
oLoZZ[1,4] = sTime;
oTL_NewBit = 2;
}
최종꼭지점 = "저점";
}
If 최종꼭지점 == "고점" Then HiLoLineZigZag = 1;
Else If 최종꼭지점 == "저점" Then HiLoLineZigZag = -1;
Else HiLoLineZigZag = 0;
즐거운 하루되세요
> 무자대기 님이 쓴 글입니다.
> 제목 : 수식확인시
> 새로작성하고 수식확인시
"선언되지 않은 이름 'HiLoLineigZag'이(가) 사용되었습니다"
라는 설명이 나옵니다. 어떻게 해야 수식이 정확히 완성되는지 알고싶습니다..
다음글
이전글