커뮤니티
지표 수식 부탁 드립니다.
2019-03-19 12:21:10
401
글번호 127181
1. 30분봉에 20선과 60선의 이평선의 평균값을 선으로 표시하고 우측에
그 값을 보여주고 싶습니다.
2. 5분봉에 60선과 240선의 이평선의 평균값을 선으로표시하고 우측에
그 값을 보여주고 싶습니다.
3. 일봉에서 20선과 60선의 이평선의 평균값을 선으로표시하고 우측에
그 값을 보여주고 싶습니다.
그리고 30분봉의 20선과 60선의 이평선 평균값을 90틱의 챠트에
보여줄수가 있는지요?
보여줄수 있다면 어떻게 설정하면 되는지 부탁 드립니다.
답변 1
예스스탁 예스스탁 답변
2019-03-19 15:59:36
안녕하세요
예스스탁입니다.
1,2,3
모두 같은 수식입니다.
원하시는 차트 주기에 적용하시면 됩니다.
20이평과 60이평의 중간값을 그리고 최종완성봉값을 텍스트로 출력합니다.
input : P1(20),P2(60);
var : tx1(0);
var1 = ma(C,P1);
var2 = ma(C,P2);
var3 = (var1+var2)/2;
plot1(var3);
Text_Delete(tx1);
tx1 = Text_New(sdate,stime,var3,NumToStr(var3,2));
4
틱차트에 참조데이타로 30분 데이타를 추가하고 아래식 적용하시면 됩니다.
input : P1(20),P2(60);
var : tx1(0);
var1 = data2(ma(C,P1));
var2 = data2(ma(C,P2));
var3 = (var1+var2)/2;
plot1(var3);
Text_Delete(tx1);
tx1 = Text_New(sdate,stime,var3,NumToStr(var3,2));
틱봉자체에서 계산하고자 하시면 틱봉에서는 타주기 분봉값을 정확히 계산하지 못합니다.
타주기는 틱봉에서는 차트의 주기보다 매수로 큰것만 계산이 가능합니다.
(100틱봉에서 300틱봉 지표, 5분봉에서 30분봉 지표)
만약 근사값으로라도 보고자 하시면 아래식 이용하시면 됩니다.
아래식은 분봉에서 타주기 분봉계산할때 사용하셔도 됩니다.
input : ntime1(30),P1(20),P2(60);
var : S1(0),D1(0),TM(0),TF(0),tx1(0);
var : cnt(0),sum1(0),mav1(0),sum2(0),mav2(0);
Array : C1[100](0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%ntime1;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF < TF[1]) Then
{
for cnt = 1 to 99
{
C1[cnt] = C1[cnt-1][1];
}
}
C1[0] = C;
if C1[P2] > 0 then{
sum1 = 0;
sum2 = 0;
for cnt = 0 to P2{
if cnt < P1 then
sum1 = sum1+C1[cnt];
if cnt < P2 then
sum2 = sum2+C1[cnt];
}
mav1 = sum1/P1;
mav2 = sum2/P2;
var1 = (mav1+mav2)/2;
plot1(var1);
Text_Delete(tx1);
tx1 = Text_New(sdate,stime,var1,NumToStr(var1,2));
}
}
즐거운 하루되세요
> 오늘도수익 님이 쓴 글입니다.
> 제목 : 지표 수식 부탁 드립니다.
> 1. 30분봉에 20선과 60선의 이평선의 평균값을 선으로 표시하고 우측에
그 값을 보여주고 싶습니다.
2. 5분봉에 60선과 240선의 이평선의 평균값을 선으로표시하고 우측에
그 값을 보여주고 싶습니다.
3. 일봉에서 20선과 60선의 이평선의 평균값을 선으로표시하고 우측에
그 값을 보여주고 싶습니다.
그리고 30분봉의 20선과 60선의 이평선 평균값을 90틱의 챠트에
보여줄수가 있는지요?
보여줄수 있다면 어떻게 설정하면 되는지 부탁 드립니다.