커뮤니티
볼밴 수식 감사하며 1분봉에서 다시 여쭙니다.
2019-02-28 19:26:46
253
글번호 126659
1) 1분봉.. (20,2) 기본 볼밴에
5분봉 (20.2) , 315분봉 (20,2) 볼밴도 함께 표현 될수 있는 수식을 부탁드립니다..
2) 위 수식 중에 분봉과 (20,2)값을 수정(변수) 가능하도록 부탁드립니
답변 1
예스스탁 예스스탁 답변
2019-03-05 09:03:13
안녕하세요
예스스탁입니다.
input : P(20),dv(2);
input : 타주기분1(5),P1(20),Dv1(2);
input : 타주기분2(315),P2(20),Dv2(2);
var : S1(0),D1(0),TM(0),cnt(0);
var : BBmd(0),BBup(0),BBdn(0);
var : TF1(0),SumSqrt1(0),Stdv1(0),sum1(0),BBmd1(0),Bbup1(0),BBdn1(0);
var : TF2(0),SumSqrt2(0),Stdv2(0),sum2(0),BBmd2(0),Bbup2(0),BBdn2(0);
Array : C1[100](0),C2[100](0);
BBmd = Ma(C,P);
BBup = BollBandUp(P,dv);
BBup = BollBandDown(P,dv);
plot1(BBmd);
plot2(BBup);
plot3(BBdn);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF1 = TM%타주기분1;
TF2 = TM%타주기분2;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF1 < TF1[1]) Then
{
for cnt = 1 to 99
{
C1[cnt] = C1[cnt-1][1];
}
}
C1[0] = C;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF2 < TF2[1]) Then
{
for cnt = 1 to 99
{
C2[cnt] = C2[cnt-1][1];
}
}
C2[0] = C;
if C1[P1] > 0 then
{
sum1 = 0;
for cnt = 0 to P1-1
{
sum1 = sum1 + C1[cnt];
}
BBmd1 = sum1/P1;
SumSqrt1 = 0;
For cnt = 0 To P1 - 1
{
SumSqrt1 = SumSqrt1 + (C1[cnt] - BBmd1)^2;
}
Stdv1 = SquareRoot(SumSqrt1 / P1);
BBup1 = BBmd1 + (Dv1 * Stdv1);
BBdn1 = BBmd1 - (Dv1 * Stdv1);
plot4(BBmd1);
plot5(BBup1);
plot6(BBdn1);
}
if C2[P2] > 0 then
{
sum2 = 0;
for cnt = 0 to P2-1
{
sum2 = sum2 + C2[cnt];
}
BBmd2 = sum2/P2;
SumSqrt2 = 0;
For cnt = 0 To P2 - 1
{
SumSqrt2 = SumSqrt2 + (C2[cnt] - BBmd2)^2;
}
Stdv2 = SquareRoot(SumSqrt2 / P2);
BBup2 = BBmd2 + (Dv2 * Stdv2);
BBdn2 = BBmd2 - (Dv2 * Stdv2);
plot7(BBmd2);
plot8(BBup2);
plot9(BBdn2);
}
}
즐거운 하루되세요
> 레드골드 님이 쓴 글입니다.
> 제목 : 볼밴 수식 감사하며 1분봉에서 다시 여쭙니다.
> 1) 1분봉.. (20,2) 기본 볼밴에
5분봉 (20.2) , 315분봉 (20,2) 볼밴도 함께 표현 될수 있는 수식을 부탁드립니다..
2) 위 수식 중에 분봉과 (20,2)값을 수정(변수) 가능하도록 부탁드립니
다음글
이전글