커뮤니티
61121재 질문 드립니다
2019-01-31 12:32:13
151
글번호 125807
첨부 이미지
그림1
수식이 꺼꾸로 된게 아닌지요 반대 방향으로 매수매도 싸인이 뜹니다
첨부 그림에서 보시다 시피 반대로 신호가 나옵니다
그리고 같은 수치를 넣고 지표와 시스템식을 보인것인데 편차가 있습니다
1번그림은 지표식에 나왔는데 그냥 없어진거구요
2번 그림은 10틱 손절내에 있었기에 저 자리가 매수 첫번째 매수자리 입니다
밀려서 54.39에 신호가 표시된거구요
3번그림은 아래보시면 매수 라고 나와있는데 고점 매도 입니다 2번에서 매수한것을
3번에 파는 것이죠 저위에 수치 54.69또한 밀려서 저리같것이구요
4번은 또한 지표에는 표시되었지만 무시된 것입니다
추가로 첫 신호나오는 자리 숫자나 다른 방법으로 구현되었으면 합니다
그리고 손절은 10틱이라고 말씀드렸는데 포함되어 있는것인지 궁금합니다
첫 숫자 나오는 자리에서 10틱 손절후 재차 매수도가 성립되는지도 궁금합니다
마지막으로 혹 소리나게끔 가능한지요
고생많으신거 아는데 조금만 신경써주셨으면 합니다
감사합니다
- 1. 파라.JPG (0.17 MB)
답변 1
예스스탁 예스스탁 답변
2019-01-31 14:20:45
안녕하세요
예스스탁입니다.
사후적으로 알수 있는 고점이나 저점봉에 신호를 발생할수는 없습니다.
해댕 부분은 수식적으로 가능하지 않습니다.
기존 진입신호는 반대로, 10틱 손실시 청산후 다음봉에 동일방향으로
다시 진입하는 내용을 추가해 드립니다.
input : af(0.02), maxAF(0.2);
input : 텍스트출력(1),손절틱수(10);
var : T(0),cnt(0),count(0);
var : HH1(0),LL1(0),HD1(0),HT1(0),LD1(0),LT1(0),day1(0),day0(0);
var : TL1(0),TL2(0),tx1(0),tx2(0),tx11(0),tx22(0);
Array : HD[20](0),HT[20](0),HH[20](0),LD[20](0),LT[20](0),LL[20](0);
var1 = CSar(af,maxAF);
if bdate != bdate[1] Then
{
day0 = sdate;
day1 = day0[1];
}
if crossup(c,var1) Then
{
T = 1;
HH[0] = H;
HD[0] = sdate;
HT[0] = stime;
for cnt = 1 to 19
{
HD[cnt] = HD[cnt-1][1];
HT[cnt] = HT[cnt-1][1];
HH[cnt] = HH[cnt-1][1];
}
if LL[0] > 0 Then
{
if 텍스트출력 == 1 then
{
Tx11 = Text_New(HD[1],HT[1],HH[1],NumToStr((HH[1]-LL[1])/PriceScale,0)+NewLine+NumToStr(HH[1],2));
Text_SetStyle(tx11,2,1);
Text_SetColor(tx11,BLACK);
Text_Delete(tx1);
Tx1 = Text_New(HD[0],HT[0],HH[0],NumToStr((HH[0]-LL[0])/PriceScale,0)+NewLine+NumToStr(HH[0],2));
Text_SetStyle(tx1,2,1);
Text_SetColor(tx1,GRAY);
sell();
Condition1 = false;
for cnt = 1 to 19
{
if Condition1 == false and abs(LL[0]-LL[cnt]) <= PriceScale*1 and LD[cnt] >= day1 Then
{
Condition1 = true;
TL1 = TL_New(LD[cnt],LT[cnt],LL[cnt],LD[0],LT[0],LL[0]);
}
}
}
}
}
if CrossDown(c,var1) Then
{
T = -1;
LL[0] = L;
LD[0] = sdate;
LT[0] = stime;
for cnt = 1 to 19
{
LD[cnt] = LD[cnt-1][1];
LT[cnt] = LT[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
}
if HH[0] > 0 Then
{
if 텍스트출력 == 1 then
{
Tx22 = Text_New(LD[1],LT[1],LL[1],NumToStr((HH[1]-LL[1])/PriceScale,0)+NewLine+NumToStr(LL[1],2));
Text_SetStyle(tx22,2,0);
Text_SetColor(tx22,RED);
Text_Delete(tx2);
Tx2 = Text_New(LD[0],LT[0],LL[0],NumToStr((HH[0]-LL[0])/PriceScale,0)+NewLine+NumToStr(LL[0],2));
Text_SetStyle(tx2,2,0);
Text_SetColor(tx2,MAGENTA);
buy();
Condition2 = false;
for cnt = 1 to 19
{
if Condition2 == false and abs(HH[0]-HH[cnt]) <= PriceScale*1 and HD[cnt] >= day1 Then
{
Condition2 = true;
TL2 = TL_New(HD[cnt],HT[cnt],HH[cnt],HD[0],HT[0],HH[0]);
}
}
}
}
}
if T == 1 then
{
if H > HH[0] Then
{
HH[0] = H;
HD[0] = sdate;
HT[0] = stime;
if 텍스트출력 == 1 then
{
Text_Delete(tx1);
Tx1 = Text_New(HD[0],HT[0],HH[0],NumToStr((HH[0]-LL[0])/PriceScale,0)+NewLine+NumToStr(HH[0],2));
Text_SetStyle(tx1,2,1);
Text_SetColor(tx1,BLACK);
}
}
}
if T == -1 then
{
if L < LL[0] Then
{
LL[0] = L;
LD[0] = sdate;
LT[0] = stime;
if 텍스트출력 == 1 then
{
Text_Delete(tx2);
Tx2 = Text_New(LD[0],LT[0],LL[0],NumToStr((HH[0]-LL[0])/PriceScale,0)+NewLine+NumToStr(LL[0],2));
Text_SetStyle(tx2,2,0);
Text_SetColor(tx2,RED);
}
}
}
if MarketPosition == 1 Then
ExitLong("bx",AtStop,EntryPrice(0)-PriceScale*손절틱수);
if MarketPosition == -1 Then
ExitShort("sx",AtStop,EntryPrice(0)+PriceScale*손절틱수);
if TotalTrades > TotalTrades[1] and MarketPosition == 0 and IsExitName("bx",1) == true then
buy("bb",AtMarket);
if TotalTrades > TotalTrades[1] and MarketPosition == 0 and IsExitName("sx",1) == true then
sell("ss",AtMarket);
즐거운 하루되세요
> 이립 님이 쓴 글입니다.
> 제목 : 61121재 질문 드립니다
> 수식이 꺼꾸로 된게 아닌지요 반대 방향으로 매수매도 싸인이 뜹니다
첨부 그림에서 보시다 시피 반대로 신호가 나옵니다
그리고 같은 수치를 넣고 지표와 시스템식을 보인것인데 편차가 있습니다
1번그림은 지표식에 나왔는데 그냥 없어진거구요
2번 그림은 10틱 손절내에 있었기에 저 자리가 매수 첫번째 매수자리 입니다
밀려서 54.39에 신호가 표시된거구요
3번그림은 아래보시면 매수 라고 나와있는데 고점 매도 입니다 2번에서 매수한것을
3번에 파는 것이죠 저위에 수치 54.69또한 밀려서 저리같것이구요
4번은 또한 지표에는 표시되었지만 무시된 것입니다
추가로 첫 신호나오는 자리 숫자나 다른 방법으로 구현되었으면 합니다
그리고 손절은 10틱이라고 말씀드렸는데 포함되어 있는것인지 궁금합니다
첫 숫자 나오는 자리에서 10틱 손절후 재차 매수도가 성립되는지도 궁금합니다
마지막으로 혹 소리나게끔 가능한지요
고생많으신거 아는데 조금만 신경써주셨으면 합니다
감사합니다