커뮤니티
수식부탁드립니다
2019-01-27 22:42:18
192
글번호 125630
항상 수고에 감사를 드립니다
아래의 2종류의 수식을 5분봉 타주기로 변환 부탁드립니다.
감사합니다.
<<1번 지표>>
Input : Period(20), MultiD(2),signal(10);
var : BBmd(0),BBup(0),BBdn(0);
BBmd = ma(C,Period);
BBup = BollBandUp(Period,MultiD);
BBdn = BollBandDown(Period,MultiD);
#1 = (상단BB -하단BB) ÷ 중간BB
var1 = (BBup-BBdn)/BBmd;
var2 = ma(var1,signal);
plot1(var1);
plot2(var2);
<<2번지표>>
input : N(10),period2(20);
var1 = (C-O)/(H-L)*V;
var2 = AccumN(var1,N);
var3 = AccumN(V,N);
var4 = var2/var3;
Var5 = ema(Var4,Period2);
plot1(var4);
plot2(var5);
PlotBaseLine1(0);
답변 1
예스스탁 예스스탁 답변
2019-01-28 14:53:02
안녕하세요
예스스탁입니다.
1
input : 타주기분(5),P(20),Dv(2),signal(10);
var : S1(0),D1(0),TM(0),TF(0);
var : cnt(0),SumSqrt(0),Stdv(0);
var : sum(0),BBmd(0),Bbup(0),BBdn(0),sum1(0),mav1(0);
Array : CC[100](0),VV[100](0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%타주기분;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF < TF[1]) Then
{
for cnt = 1 to 99
{
CC[cnt] = CC[cnt-1][1];
VV[cnt] = VV[cnt-1][1];
}
}
CC[0] = C;
if CC[P] > 0 then
{
sum = 0;
for cnt = 0 to P-1
{
sum = sum + CC[cnt];
}
BBmd = sum/P;
SumSqrt = 0;
For cnt = 0 To P - 1
{
SumSqrt = SumSqrt + (CC[cnt] - BBmd)^2;
}
Stdv = SquareRoot(SumSqrt / P);
BBup = BBmd + (Dv * Stdv);
BBdn = BBmd - (Dv * Stdv);
VV[0] = (BBup-BBdn)/BBmd;
plot1(VV[0]);
}
if VV[signal] > 0 Then
{
sum1 = 0;
for cnt = 0 to signal-1
{
sum1 = sum1 + VV[cnt];
}
mav1 = sum1/signal;
plot2(mav1);
}
}
2
input : 타주기분(5),N(10),Period2(20);
var : S1(0),D1(0),TM(0),TF(0),cnt(0);
var : V2(0),V3(0),V4(0),EP(0),V5(0),Pre(0);
Array : OO[100](0),HH[100](0),LL[100](0),CC[100](0),VV[100](0);
Array : V1[100](0);
Ep = 2/(Period2+1);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%타주기분;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF < TF[1]) Then
{
OO[0] = O;
HH[0] = H;
LL[0] = L;
VV[0] = 0;
for cnt = 1 to 99
{
CC[cnt] = CC[cnt-1][1];
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
CC[cnt] = CC[cnt-1][1];
VV[cnt] = VV[cnt-1][1];
V1[cnt] = V1[cnt-1][1];
}
Pre = V5;
}
VV[0] = VV[0]+v;
CC[0] = C;
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
v1[0] = (CC[0]-OO[0])/(HH[0]-LL[0])*VV[0];
if V1[N] != 0 Then
{
V2 = 0;
V3 = 0;
for cnt = 0 to N-1
{
V2 = V2 + V1[cnt];
V3 = V3 + VV[cnt];
}
V4 = V2/V3;
plot1(v4);
if pre == 0 then
V5 = C;
else
V5 = V4 * EP + Pre * (1-EP);
plot2(v5);
}
}
PlotBaseLine1(0);
즐거운 하루되세요
> 천년대로 님이 쓴 글입니다.
> 제목 : 수식부탁드립니다
> 항상 수고에 감사를 드립니다
아래의 2종류의 수식을 5분봉 타주기로 변환 부탁드립니다.
감사합니다.
<<1번 지표>>
Input : Period(20), MultiD(2),signal(10);
var : BBmd(0),BBup(0),BBdn(0);
BBmd = ma(C,Period);
BBup = BollBandUp(Period,MultiD);
BBdn = BollBandDown(Period,MultiD);
#1 = (상단BB -하단BB) ÷ 중간BB
var1 = (BBup-BBdn)/BBmd;
var2 = ma(var1,signal);
plot1(var1);
plot2(var2);
<<2번지표>>
input : N(10),period2(20);
var1 = (C-O)/(H-L)*V;
var2 = AccumN(var1,N);
var3 = AccumN(V,N);
var4 = var2/var3;
Var5 = ema(Var4,Period2);
plot1(var4);
plot2(var5);
PlotBaseLine1(0);
다음글
이전글