커뮤니티
문위 드립니다
2018-11-16 11:38:09
226
글번호 123735
INPUT: MALEN(10),CONST(0.8),ATRs(0);
VAR: CENTLINE(0), AVGRANGE(0), UPPER(0), LOWER(0);
CENTLINE=KeltnerChannel(Close, MALEN, ATRs);
AVGRANGE=Ma(TRUERANGE(),MALEN);
UPPER=CENTLINE+(AVGRANGE*CONST);
LOWER=CENTLINE-(AVGRANGE*CONST);
PLOT1(CENTLINE,"CENTLINE");
PLOT2(UPPER,"UPPER");
PLOT3(LOWER,"LOWER");
위에 지표를 10분에 나오는것을 1분봉으로 나오게 할수있는지요
2,,,,일봉으로 3,5,10,20 이평을 1분봉으로 구현할수 있을까요
3,,,,,전일에 가격에 중심값을 당일에 볼수있게 해주세요
감사드리고 부탁드립니다
답변 1
예스스탁 예스스탁 답변
2018-11-19 09:25:27
안녕하세요
예스스탁입니다.
1.
input : 타주기분(10);
INPUT: MALEN(10),CONST(0.8),ATRs(0);
var : S1(0),D1(0),TM(0),TF(0),cnt(0),HH(0),LL(0);
var : sumTR(0),ATRV(0),sum(0),mav(0);
VAR: CENTLINE(0), AVGRANGE(0), UPPER(0), LOWER(0);
Array : TH[100](0),TL[100](0),CC[100](0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%타주기분;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and (TF < TF[1] or TM >= TM[1]+타주기분)) Then
{
HH = H;
LL = L;
for cnt = 1 to 99
{
TH[cnt] = TH[cnt-1][1];
TL[cnt] = TL[cnt-1][1];
CC[cnt] = CC[cnt-1][1];
}
}
if H > HH Then
HH = H;
if L < LL Then
LL = L;
CC[0] = c;
TH[0] = max(CC[1],HH);
TL[0] = Min(CC[1],LL);
if TH[MALEN-1] > 0 and TL[MALEN-1] > 0 then
{
sum = 0;
sumTR = 0;
for cnt = 0 to MALEN-1
{
sum = sum + CC[cnt];
sumTR = sumTR + (TH[cnt]-TL[cnt]);
}
ATRV = sumTR/MALEN;
mav = sum/MALEN;
CENTLINE = mav+ ATRv * ATRs;
AVGRANGE = ATRV;
UPPER=CENTLINE+(AVGRANGE*CONST);
LOWER=CENTLINE-(AVGRANGE*CONST);
PLOT1(CENTLINE,"CENTLINE");
PLOT2(UPPER,"UPPER");
PLOT3(LOWER,"LOWER");
}
}
2
input : P1(3),P2(5),P3(10),P4(20);
var : count(0);
var : sumV1(0),sumV2(0),sumV3(0),sumV4(0);
var : mav1(0),mav2(0),mav3(0),mav4(0);
sumV1 = 0;
sumV2 = 0;
sumV3 = 0;
sumV4 = 0;
for count = 0 to P3{
if count < P1 Then
sumV1 = sumV1+DayClose(count);
if count < P2 Then
sumV2 = sumV2+DayClose(count);
if count < P3 Then
sumV3 = sumV3+DayClose(count);
if count < P4 Then
sumV4 = sumV4+DayClose(count);
}
maV1 = sumV1 / P1;
maV2 = sumV2 / P2;
maV3 = sumV3 / P3;
maV4 = sumV4 / P4;
plot1(mav1);
plot2(mav2);
plot3(mav3);
plot4(mav4);
3
var1 = (DayHigh(1)+daylow(1))/2;
plot1(var1);
즐거운 하루되세요
> 이공주7 님이 쓴 글입니다.
> 제목 : 문위 드립니다
> INPUT: MALEN(10),CONST(0.8),ATRs(0);
VAR: CENTLINE(0), AVGRANGE(0), UPPER(0), LOWER(0);
CENTLINE=KeltnerChannel(Close, MALEN, ATRs);
AVGRANGE=Ma(TRUERANGE(),MALEN);
UPPER=CENTLINE+(AVGRANGE*CONST);
LOWER=CENTLINE-(AVGRANGE*CONST);
PLOT1(CENTLINE,"CENTLINE");
PLOT2(UPPER,"UPPER");
PLOT3(LOWER,"LOWER");
위에 지표를 10분에 나오는것을 1분봉으로 나오게 할수있는지요
2,,,,일봉으로 3,5,10,20 이평을 1분봉으로 구현할수 있을까요
3,,,,,전일에 가격에 중심값을 당일에 볼수있게 해주세요
감사드리고 부탁드립니다
이전글