커뮤니티
재 질문입니다.
2018-11-07 22:45:44
148
글번호 123463
안녕하세요
번호 59985 에서 수평선 오른쪽에 선의 수치를 나오게
하고 싶습니다. 감사합니다.
답변 1
예스스탁 예스스탁 답변
2018-11-09 10:37:00
안녕하세요
예스스탁입니다.
Input:전환비율(0.5),종가사용여부(0),파동선두께(2),수치표시(1);
Var:j(0),jj(0),HH(0),LL(0),hiBar(0),loBar(0),최종꼭지점(""),처리구분(""),
TL1(0),Text1(0),TL11(0),TL12(0),TL13(0),tx11(0),tx12(0);
Array:고[10,4](0),저[10,4](0);
HH = IFF(종가사용여부 == 1,C,H);
LL = IFF(종가사용여부 == 1,C,L);
If Index == 0 Then
{
고[1,1] = HH;
고[1,2] = 0;
고[1,3] = sDate;
고[1,4] = sTime;
저[1,1] = LL;
저[1,2] = 0;
저[1,3] = sDate;
저[1,4] = sTime;
}
If Index > 0 Then
{
hiBar = hiBar + 1;
loBar = loBar + 1;
}
If HH[hiBar] < HH Then hiBar = 0;
If LL[loBar] > LL Then loBar = 0;
Condition1 = 저[1,1] * (1 + (전환비율/100)) < HH and hiBar == 0;
Condition2 = 고[1,1] * (1 - (전환비율/100)) > LL and loBar == 0;
처리구분 = "";
If Condition1 and Condition2 Then
{
If 최종꼭지점 == "저점" Then
{
If 저[1,1] > LL Then 처리구분 = "저점처리";
Else 처리구분 = "고점처리";
}
Else If 최종꼭지점 == "고점" Then
{
If 고[1,1] < HH Then 처리구분 = "고점처리";
Else 처리구분 = "저점처리";
}
}
Else If Condition1 Then 처리구분 = "고점처리";
Else If Condition2 Then 처리구분 = "저점처리";
If 처리구분 == "고점처리" Then
{
If 최종꼭지점 == "저점" Then
{
For j = 10 DownTo 2
{
For jj = 1 To 4
{
고[j,jj] = 고[j-1,jj];
}
}
고[1,1] = HH[hiBar];
고[1,2] = Index - hiBar;
고[1,3] = sDate[hiBar];
고[1,4] = sTime[hiBar];
hiBar = -1;
loBar = -1;
TL1 = TL_New(저[1,3],저[1,4],저[1,1],고[1,3],고[1,4],고[1,1]);
TL_Delete(TL11);
TL_Delete(TL12);
TL_Delete(TL13);
TL11 = TL_New(저[1,3],저[1,4],999999999,저[1,3],저[1,4],0);
TL12 = TL_New(고[2,3],고[2,4],저[1,1],고[1,3],고[1,4],저[1,1]);
TL13 = TL_New(고[2,3],고[2,4],저[1,1]* (1 + (전환비율/100)) ,고[1,3],고[1,4],저[1,1]* (1 + (전환비율/100)) );
TL_SetExtRight(TL12,true);
TL_SetExtRight(TL13,true);
Text_Delete(tx11);
Text_Delete(tx12);
tx11 = Text_New(sdate,stime,저[1,1],NumToStr(저[1,1],2));
tx12 = Text_New(sdate,stime,저[1,1]* (1 + (전환비율/100)),NumToStr(저[1,1]* (1 + (전환비율/100)),2));
Text_SetStyle(tx11,0,0);
Text_SetStyle(tx12,0,0);
If 수치표시 == 1 Then
{
Text1 = Text_New(고[1,3],고[1,4],고[1,1],NumToStr(고[1,1],2));
Text_SetStyle(Text1, 2, 1);
}
TL_SetSize(TL1,파동선두께);
TL_SetColor(TL1,red);
}
Else If 고[1,1] < HH[hiBar] Then
{
고[1,1] = HH[hiBar];
고[1,2] = Index - hiBar;
고[1,3] = sDate[hiBar];
고[1,4] = sTime[hiBar];
hiBar = -1;
loBar = -1;
TL_SetEnd(TL1,고[1,3],고[1,4],고[1,1]);
If 수치표시 == 1 Then
{
Text_SetLocation(Text1,고[1,3],고[1,4],고[1,1]);
Text_SetString(Text1,NumToStr(고[1,1],2));
}
}
최종꼭지점 = "고점";
}
If 처리구분 == "저점처리" Then
{
If 최종꼭지점 == "고점" Then
{
For j = 10 DownTo 2
{
For jj = 1 To 4
{
저[j,jj] = 저[j-1,jj];
}
}
저[1,1] = LL[loBar];
저[1,2] = Index - loBar;
저[1,3] = sDate[loBar];
저[1,4] = sTime[loBar];
hiBar = -1;
loBar = -1;
TL1 = TL_New(고[1,3],고[1,4],고[1,1],저[1,3],저[1,4],저[1,1]);
TL_Delete(TL11);
TL_Delete(TL12);
TL_Delete(TL13);
TL11 = TL_New(고[1,3],고[1,4],999999999,고[1,3],고[1,4],0);
TL12 = TL_New(저[2,3],저[2,4],고[1,1],저[1,3],저[1,4],고[1,1]);
TL13 = TL_New(저[2,3],저[2,4],고[1,1]* (1 - (전환비율/100)) ,저[1,3],저[1,4],고[1,1]* (1 - (전환비율/100)) );
TL_SetExtRight(TL12,true);
TL_SetExtRight(TL13,true);
Text_Delete(tx11);
Text_Delete(tx12);
tx11 = Text_New(sdate,stime,고[1,1],NumToStr(고[1,1],2));
tx12 = Text_New(sdate,stime,고[1,1]* (1 - (전환비율/100)),NumToStr(고[1,1]* (1 - (전환비율/100)),2));
Text_SetStyle(tx11,0,0);
Text_SetStyle(tx12,0,0);
If 수치표시 == 1 Then
{
Text1 = Text_New(저[1,3],저[1,4],저[1,1],NumToStr(저[1,1],2));
Text_SetStyle(Text1, 2, 0);
}
TL_SetSize(TL1,파동선두께);
TL_SetColor(TL1,blue);
}
Else If 저[1,1] > LL[loBar] Then
{
저[1,1] = LL[loBar];
저[1,2] = Index - loBar;
저[1,3] = sDate[loBar];
저[1,4] = sTime[loBar];
hiBar = -1;
loBar = -1;
TL_SetEnd(TL1,저[1,3],저[1,4],저[1,1]);
If 수치표시 == 1 Then
{
Text_SetLocation(Text1,저[1,3],저[1,4],저[1,1]);
Text_SetString(Text1,NumToStr(저[1,1],2));
}
}
최종꼭지점 = "저점";
}
if 최종꼭지점 == "고점" Then
{
Text_SetLocation(tx11,sdate,stime,저[1,1]);
Text_SetLocation(tx12,sdate,stime,저[1,1]* (1 + (전환비율/100)));
}
else
{
Text_SetLocation(tx11,sdate,stime,고[1,1]);
Text_SetLocation(tx12,sdate,stime,고[1,1]* (1 - (전환비율/100)));
}
즐거운 하루되세요
> 동해바다01 님이 쓴 글입니다.
> 제목 : 재 질문입니다.
> 안녕하세요
번호 59985 에서 수평선 오른쪽에 선의 수치를 나오게
하고 싶습니다. 감사합니다.