커뮤니티
수식 부탁드립니다
2018-09-11 08:41:18
190
글번호 121930
다음 수식 좀 부탁드립니다.
- 초기투자자금은 1억원으로 하여,
- 주식 (kodex 200 혹은 kodex 레버리지 etf)과 현금을 50:50로 투자하고,
방법1):
- 초기투자자금 대비하여 10 % 이상 +/- 변동 시마다 50:50으로 리밸런싱 하는 방법.
방법2):
- 주식평가액이 10% 이상 +/- 변동 시마다 50:50으로 리밸런싱 하는 방법.
감사합니다.
답변 1
예스스탁 예스스탁 답변
2018-09-11 15:04:51
안녕하세요
예스스탁입니다.
모두 피라미딩을 모든진입신호 허용으로 설정하고 적용하셔야 합니다.
1
input : MM(100000000);
var : VV(0),H1(0),M1(0),D1(0),vol(0);
VV = MM+NetProfit+PositionProfit;
if index == 0 Then
{
M1 = VV;
H1 = VV*0.5;
vol = Floor(H1/C);
buy("b",OnClose,def,vol);
}
Else
{
if VV >= M1*1.10 or VV <= M1*0.90 Then
{
M1 = VV;
H1 = VV*0.5;
D1 = C*CurrentContracts-H1;
if D1 > 0 and abs(D1) > C Then
{
vol = Ceiling(D1/C);
ExitLong("bx",OnClose,def,"",vol,2);
}
if D1 < 0 and abs(D1) > C Then
{
vol = Floor(abs(D1)/C);
Buy("bb",OnClose,def,vol);
}
}
}
2
input : MM(100000000);
var : VV(0),H1(0),M1(0),D1(0),vol(0),C1(0);
VV = MM+NetProfit+PositionProfit;
if index == 0 Then
{
M1 = VV;
H1 = VV*0.5;
vol = Floor(H1/C);
C1 = C*vol;
buy("b",OnClose,def,vol);
}
Else
{
if C*CurrentContracts >= C1*1.10 or C*CurrentContracts <= C1*0.90 Then
{
M1 = VV;
H1 = VV*0.5;
D1 = C*CurrentContracts-H1;
if D1 > 0 and abs(D1) > C Then
{
vol = Ceiling(D1/C);
C1 = C*(CurrentContracts-vol);
ExitLong("bx",OnClose,def,"",vol,2);
}
if D1 < 0 and abs(D1) > C Then
{
vol = Floor(abs(D1)/C);
C1 = C*(CurrentContracts+vol);
Buy("bb",OnClose,def,vol);
}
}
}
즐거운 하루되세요
> theogo66 님이 쓴 글입니다.
> 제목 : 수식 부탁드립니다
> 다음 수식 좀 부탁드립니다.
- 초기투자자금은 1억원으로 하여,
- 주식 (kodex 200 혹은 kodex 레버리지 etf)과 현금을 50:50로 투자하고,
방법1):
- 초기투자자금 대비하여 10 % 이상 +/- 변동 시마다 50:50으로 리밸런싱 하는 방법.
방법2):
- 주식평가액이 10% 이상 +/- 변동 시마다 50:50으로 리밸런싱 하는 방법.
감사합니다.
다음글
이전글