커뮤니티
당일 매매 프로그램 여쭤봅니다
2018-04-09 01:13:46
181
글번호 118023
제가 rsi(14,30,70) 함수를 사용하는데
이 함수가 현재 봉에서 14개전의 봉을 가지고 계산을 합니다.
저는 전날의 데이터는 사용하고싶지않아서
당일의 데이터만을 사용해서 백테스팅을 해보고싶은데, 어떤 함수같은게 있을까요?
당일 데이터만 사용하게 하는 방법이 있을까요?
답변 1
예스스탁 예스스탁 답변
2018-04-09 14:29:33
안녕하세요
예스스탁입니다.
당일데이터만 이용하게 작성한 식입니다.
Input : Length(14);
Var : Counter(0), DownAmt(0), UpAmt(0), UpSum(0), DownSum(0);
var : UpAvg(0), DownAvg(0), idx(0),RSIv(0);
if bdate != bdate[1] Then
idx = 0;
Else
idx = idx+1;
If idx <= Length Then
{
UpSum = 0;
DownSum = 0;
For Counter = 0 To idx - 1
{
UpAmt = C[Counter] - C[Counter+1];
If UpAmt >= 0 Then
DownAmt = 0;
Else
{
DownAmt = -UpAmt;
UpAmt = 0;
}
UpSum = UpSum + UpAmt;
DownSum = DownSum + DownAmt;
}
UpAvg = UpSum / (idx+1);
DownAvg = DownSum / (idx+1);
}
Else If idx > Length Then {
UpAmt = C[0] - C[1];
If UpAmt >= 0 Then
DownAmt = 0;
Else
{
DownAmt = -UpAmt;
UpAmt = 0;
}
UpAvg = (UpAvg[1] * (Length - 1) + UpAmt) / Length;
DownAvg = (DownAvg[1] * (Length - 1) + DownAmt) / Length;
}
If UpAvg + DownAvg <> 0 Then
RSIv = 100 * UpAvg / (UpAvg + DownAvg);
Else
RSIv = 0;
plot1(RSIV);
즐거운 하루되세요
> 몽거루 님이 쓴 글입니다.
> 제목 : 당일 매매 프로그램 여쭤봅니다
> 제가 rsi(14,30,70) 함수를 사용하는데
이 함수가 현재 봉에서 14개전의 봉을 가지고 계산을 합니다.
저는 전날의 데이터는 사용하고싶지않아서
당일의 데이터만을 사용해서 백테스팅을 해보고싶은데, 어떤 함수같은게 있을까요?
당일 데이터만 사용하게 하는 방법이 있을까요?
다음글
이전글