커뮤니티
56638 문의글 재질문 입니다.
2018-02-15 17:47:33
224
글번호 116667
첨부 이미지
그림1
그림2
지표가 재대로 표시되지않는것 같습니다. 예를들어
1분봉에서 타주기분을 1분으로 설정하면 일반적인 볼린저밴드가 표현되어야 되는데 표시가 안되네요
1번그림은 왼쪽이 1분봉이고 오른쪽이 5분봉인데요 1분봉에서 5분봉 지표 모양 그대로 표현을
하고 싶습니다.
2번그림 처럼 5분봉의 볼린저밴드의 모양 그대로 1분봉에서 표현하고 싶은거죠
물론 분이 늘어난 만큼 간격은 커지겠지만요.
또한 피리어드를 200이상 설정해서 사용하는데 100 이상으로 표시가 되지 않더군요
수정좀 가능할까요?
따뜻한 명절 연휴 되십시요 ^^
답변 1
예스스탁 예스스탁 답변
2018-02-19 11:30:32
안녕하세요
예스스탁입니다.
타주기의 지표는 차트의 주기보다 배수로 높은 주기만 가능합니다.
(5분차트에서 10분, 15분) --> 가능
차트의 주기보다 낮은 주기와
배수가 맞지 않은 주기는 계산이 불가능합니다.
(5분차트에서 1분, 8분) --> 불가
또한 항셍과 같이 거래소의 영업일 변경시간과 사용자분이 보는 영엽일 변경이
다른 종목은 별도로 처리해야 합니다.
이용에 참고하시기 바랍니다.
1
항셍용
input : 타주기분(60),P(20),Dv(2);
var : S1(0),D1(0),TM(0),TF(0),cnt(0),SumSqrt(0),Stdv(0);
var : sum(0),BBmd(0),Bbup(0),BBdn(0);
Array : CC[100](0);
if (sdate != sdate[1] and stime >= 100000) or
(sdate == sdate[1] and stime >= 100000 and stime[1] < 100000) Then{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%타주기분;
if (sdate != sdate[1] and stime >= 100000) or
(sdate == sdate[1] and stime >= 100000 and stime[1] < 100000) or
(sdate == sdate[1] and 타주기분 > 1 and TF < TF[1]) or
(sdate == sdate[1] and 타주기분 == 1 and TM > TM[1]) Then{
for cnt = 1 to 99{
CC[cnt] = CC[cnt-1][1];
}
}
CC[0] = C;
if CC[P] > 0 then{
sum = 0;
for cnt = 0 to P-1{
sum = sum + CC[cnt];
}
BBmd = sum/P;
SumSqrt = 0;
For cnt = 0 To P - 1 {
SumSqrt = SumSqrt + (CC[cnt] - BBmd)^2;
}
Stdv = SquareRoot(SumSqrt / P);
BBup = BBmd + (Dv * Stdv);
BBdn = BBmd - (Dv * Stdv);
plot1(BBmd);
plot2(BBup);
plot3(BBdn);
}
}
2 일반
input : 타주기분(60),P(20),Dv(2);
var : S1(0),D1(0),TM(0),TF(0),cnt(0),SumSqrt(0),Stdv(0);
var : sum(0),BBmd(0),Bbup(0),BBdn(0);
Array : CC[100](0);
if bdate != bdate[1] Then{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%타주기분;
if bdate != bdate[1] or
(bdate == bdate[1] and 타주기분 > 1 and TF < TF[1]) or
(bdate == bdate[1]and 타주기분 == 1 and TM > TM[1]) Then{
for cnt = 1 to 99{
CC[cnt] = CC[cnt-1][1];
}
}
CC[0] = C;
if CC[P] > 0 then{
sum = 0;
for cnt = 0 to P-1{
sum = sum + CC[cnt];
}
BBmd = sum/P;
SumSqrt = 0;
For cnt = 0 To P - 1 {
SumSqrt = SumSqrt + (CC[cnt] - BBmd)^2;
}
Stdv = SquareRoot(SumSqrt / P);
BBup = BBmd + (Dv * Stdv);
BBdn = BBmd - (Dv * Stdv);
plot1(BBmd);
plot2(BBup);
plot3(BBdn);
}
}
즐거운 하루되세요
> dbs1428 님이 쓴 글입니다.
> 제목 : 56638 문의글 재질문 입니다.
> 지표가 재대로 표시되지않는것 같습니다. 예를들어
1분봉에서 타주기분을 1분으로 설정하면 일반적인 볼린저밴드가 표현되어야 되는데 표시가 안되네요
1번그림은 왼쪽이 1분봉이고 오른쪽이 5분봉인데요 1분봉에서 5분봉 지표 모양 그대로 표현을
하고 싶습니다.
2번그림 처럼 5분봉의 볼린저밴드의 모양 그대로 1분봉에서 표현하고 싶은거죠
물론 분이 늘어난 만큼 간격은 커지겠지만요.
또한 피리어드를 200이상 설정해서 사용하는데 100 이상으로 표시가 되지 않더군요
수정좀 가능할까요?
따뜻한 명절 연휴 되십시요 ^^