커뮤니티
부탁드립니다.
2017-12-15 08:07:26
188
글번호 115012
도움주심에 감사 드립니다
타주기에서(분용,틱용)지표를 보고자 부탁 드립니다.
미리 감사 드립니다.
inputs: bd(20),g(1);
var:wn(0),ab(0),b1(0),c1(0),c2(0),c3(0),filt(0),peak(0),universal(0),universal_m(0);
wn=(c-c[2])/2;
ab=ExpValue(-1.73*3/bd);
b1=2*ab*cosine(1.4*180/bd);
c2=b1;
c3=-ab*ab;
c1=1-c2-c3;
if accum(1)>3 then {
filt=c1*(wn+wn[1])/2+c2*filt[1]+c3*filt[2];
}
peak=0.73*peak[1];
if CurrentBar==1 then peak=0.0001;
if AbsValue(filt)>peak then peak= absvalue (filt);
if peak <> 0 then universal= ema(filt/peak,g);
답변 1
예스스탁 예스스탁 답변
2017-12-15 17:42:31
안녕하세요
예스스탁입니다.
1.
input : 타주기_분용(60);
inputs : bd(20),g(1);
var : ab(0),b1(0),c1(0),c2(0),c3(0),universal(0),universal_m(0);
var : S1(0),D1(0),TM(0),TF(0),cnt(0),idx(0),ep(0),PreEma(0);
Array : CC[10](0),wn[10](0),filt[10](0),peak[10](0);
ep = 2/(g+1);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%타주기_분용;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF < TF[1]) Then
{
idx = idx+1;
for cnt = 1 to 9{
CC[cnt] = CC[cnt-1][1];
wn[cnt] = wn[cnt-1][1];
filt[cnt] = filt[cnt-1][1];
peak[cnt] = peak[cnt-1][1];
}
PreEma = universal[1];
}
CC[0] = C;
if idx >= 3 then
{
wn[0] = (CC[0]-CC[2])/2;
ab = ExpValue(-1.73*3/bd);
b1 = 2*ab*cosine(1.4*180/bd);
c2 = b1;
c3 = -ab*ab;
c1 = 1-c2-c3;
}
if idx >= 4 then
{
filt[0] = c1*(wn[0]+wn[1])/2+c2*filt[1]+c3*filt[2];
}
peak[0] = 0.73*peak[1];
if idx == 4 then
{
peak[0] = 0.0001;
}
if AbsValue(filt[0]) > peak[0] then
peak[0] = absvalue(filt[0]);
if idx >= 5 then
{
universal = filt[0]/peak[0] * EP + PreEma * (1-EP);
plot1(universal);
}
}
2
input : 틱배수(2);
inputs : bd(20),g(1);
var : ab(0),b1(0),c1(0),c2(0),c3(0),universal(0),universal_m(0),ii(0);
var : S1(0),D1(0),TM(0),TF(0),cnt(0),idx(0),ep(0),PreEma(0);
Array : CC[10](0),wn[10](0),filt[10](0),peak[10](0);
ep = 2/(g+1);
if Bdate != Bdate[1] Then
ii = 0;
Else
ii = ii+1;
TF = ii%틱배수;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF < TF[1]) Then
{
idx = idx+1;
for cnt = 1 to 9{
CC[cnt] = CC[cnt-1][1];
wn[cnt] = wn[cnt-1][1];
filt[cnt] = filt[cnt-1][1];
peak[cnt] = peak[cnt-1][1];
}
PreEma = universal[1];
}
CC[0] = C;
if idx >= 3 then
{
wn[0] = (CC[0]-CC[2])/2;
ab = ExpValue(-1.73*3/bd);
b1 = 2*ab*cosine(1.4*180/bd);
c2 = b1;
c3 = -ab*ab;
c1 = 1-c2-c3;
}
if idx >= 4 then
{
filt[0] = c1*(wn[0]+wn[1])/2+c2*filt[1]+c3*filt[2];
}
peak[0] = 0.73*peak[1];
if idx == 4 then
{
peak[0] = 0.0001;
}
if AbsValue(filt[0]) > peak[0] then
peak[0] = absvalue(filt[0]);
if idx >= 5 then
{
universal = filt[0]/peak[0] * EP + PreEma * (1-EP);
plot1(universal);
}
즐거운 하루되세요
> yes 님이 쓴 글입니다.
> 제목 : 부탁드립니다.
> 도움주심에 감사 드립니다
타주기에서(분용,틱용)지표를 보고자 부탁 드립니다.
미리 감사 드립니다.
inputs: bd(20),g(1);
var:wn(0),ab(0),b1(0),c1(0),c2(0),c3(0),filt(0),peak(0),universal(0),universal_m(0);
wn=(c-c[2])/2;
ab=ExpValue(-1.73*3/bd);
b1=2*ab*cosine(1.4*180/bd);
c2=b1;
c3=-ab*ab;
c1=1-c2-c3;
if accum(1)>3 then {
filt=c1*(wn+wn[1])/2+c2*filt[1]+c3*filt[2];
}
peak=0.73*peak[1];
if CurrentBar==1 then peak=0.0001;
if AbsValue(filt)>peak then peak= absvalue (filt);
if peak <> 0 then universal= ema(filt/peak,g);