커뮤니티
부탁드립니다.
2017-12-12 22:55:34
173
글번호 114936
항상 친절하시고 빠른 답변 고맙습니다.
아래 식을 10분봉에서 일봉의 adx로 표시하는 방법과
30분봉에서 일봉의 adx로 표시하는 방법을 알려 주시면 고맙겠습니다.
input : Period(60);
var : ADXv(0),DP(0),DM(0),DA(0), DAUP(0), DADN(0);
ADXv = ADX(Period);
DP = DiPlus(Period);
DM = DiMinus(Period);
DA = (DP*0.5)+(DM*0.5);
DAUP = DA*1.05;
DADN = DA*0.95;
plot1(ADXv,"ADX");
plot2(DP,"+DI");
plot3(DM,"-DI");
PlotBaseLine1(DA, "기준선", BLACK, def, 1);
답변 1
예스스탁 예스스탁 답변
2017-12-13 15:15:03
안녕하세요
예스스탁입니다.
분봉이하(분/초/틱)에서 일봉지표를 그리는 것은 모두 같습니다.
분봉주기별로 다르지 않습니다.
input : Length(14);
var : TL(0),TH(0),cnt(0),Dcnt(0),preTRange(0),prePlusDM14(0),DMinus(0),MinusDM14(0),TRange1(0),preMinusDM14(0);
Var : Counter(0), TRange(0), MyRange(Length), PlusDM14(0), PlusDM(0), MinusDM(0),Dplus(0),preADX(0);
Var : CummDMI(0), Return(0);
var : DA(0), DAUP(0), DADN(0);
Array : HH[61](0),LL[61](0),CC[61](0),TR[61](0),DMIv[61](0),ADXv[61](0);
if date != date[1] Then{
Dcnt = Dcnt+1;
HH[0] = H;
LL[0] = L;
CC[0] = C;
preTRange = TRange[1];
prePlusDM14 = PlusDM14[1];
preMinusDM14 = MinusDM14[1];
for cnt = 1 to 60{
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
CC[cnt] = CC[cnt-1][1];
TR[cnt] = TR[cnt-1][1];
DMIv[cnt] = DMIv[cnt-1][1];
ADXv[cnt] = ADXv[cnt-1][1];
}
}
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
CC[0] = C;
if CC[1] > 0 Then{
If CC[1] > HH[0] then
TH = CC[1];
else
TH = HH[0];
If CC[1] < LL[0] then
TL = CC[1];
else
TL = LL[0];
TR[0] = TH-TL;
}
If Dcnt == Length+1 Then {
MyRange = Length;
DPlus = 0;
PlusDM14 = 0;
TRange = 0;
DMinus = 0;
MinusDM14 = 0;
TRange1 = 0;
For Counter = 0 To MyRange - 1 {
If HH[Counter] - HH[Counter+1] < 0 Then
PlusDM = 0 ;
Else
PlusDM = HH[Counter] - HH[Counter+1];
If LL[Counter+1] - LL[Counter] < 0 Then
MinusDM = 0;
Else
MinusDM = LL[Counter+1] - LL[Counter];
If MinusDM >= PlusDM Then
PlusDM = 0;
If PlusDM >= MinusDM Then
MinusDM = 0;
TRange = TRange + TR[Counter];
PlusDM14 = PlusDM14 + PlusDM;
MinusDM14 = MinusDM14 + MinusDM;
}
If TRange <> 0 Then
DPlus = 100 * PlusDM14 / TRange;
Else
DPlus = 0 ;
If TRange <> 0 Then
DMinus = 100 * MinusDM14 / TRange;
Else
DMinus = 0;
If Dplus + Dminus == 0 Then
DMIv[0] = 0;
Else
DMIv[0] = 100 * AbsValue(Dplus - Dminus) / (Dplus + Dminus);
}
Else If Dcnt > Length+1 Then {
If HH[0] - HH[1] < 0 Then
PlusDM = 0;
Else
PlusDM = HH[0] - HH[1];
If LL[1] - LL[0] < 0 Then
MinusDM = 0;
Else
MinusDM = LL[1] - LL[0];
If MinusDM >= PlusDM Then
PlusDM = 0;
If PlusDM >= MinusDM Then
MinusDM = 0 ;
If MyRange > 0 Then {
TRange = preTRange - (preTRange / MyRange) + TR[0];
PlusDM14 = prePlusDM14 - (prePlusDM14 / MyRange) + PlusDM;
MinusDM14 = preMinusDM14 - (preMinusDM14 / MyRange) + MinusDM;
}
If TRange <> 0 Then
DPlus = 100 * PlusDM14 / TRange;
Else
DPlus = 0 ;
If TRange <> 0 Then
DMinus = 100 * MinusDM14 / TRange;
Else
DMinus = 0;
If Dplus + Dminus == 0 Then
DMIv[0] = 0;
Else
DMIv[0] = 100 * AbsValue(Dplus - Dminus) / (Dplus + Dminus);
}
If DMIV[Length] == 0 Then{
CummDMI = 0;
for Counter = 0 To Length-1 Begin
if DMiV[counter] > 0 Then
CummDMI = CummDMI + DMIV[Counter];
End;
ADXv[0] = CummDMI / CurrentBar;
}
Else
ADXv[0] = (ADXv[1] * (Length - 1) + DMIv[0]) / Length;
DA = (Dplus*0.5)+(Dminus+0.5);
DAUP = DA*1.05;
DADN = DA*0.95;
plot1(ADXv[0],"ADX");
plot2(Dplus,"+DI");
plot3(Dminus,"-DI");
PlotBaseLine1(DA, "기준선", BLACK, def, 1);
즐거운 하루되세요
> 민기삼촌 님이 쓴 글입니다.
> 제목 : 부탁드립니다.
> 항상 친절하시고 빠른 답변 고맙습니다.
아래 식을 10분봉에서 일봉의 adx로 표시하는 방법과
30분봉에서 일봉의 adx로 표시하는 방법을 알려 주시면 고맙겠습니다.
input : Period(60);
var : ADXv(0),DP(0),DM(0),DA(0), DAUP(0), DADN(0);
ADXv = ADX(Period);
DP = DiPlus(Period);
DM = DiMinus(Period);
DA = (DP*0.5)+(DM*0.5);
DAUP = DA*1.05;
DADN = DA*0.95;
plot1(ADXv,"ADX");
plot2(DP,"+DI");
plot3(DM,"-DI");
PlotBaseLine1(DA, "기준선", BLACK, def, 1);