커뮤니티
문의드립니다.
2017-11-29 04:49:11
154
글번호 114549
날씨가 많이 추워졌습니다. 감기조심하시구요.
아래와 같은 수식을 부탁드립니다.
1.매매시간
17시 ~ 04시까지 매매후 종료(섬머타임때는 16시 ~ 03시까지)
2.진입조건(2계약 진입)
매수 : 20일선 우상향 하고 캔들이 20일선 아래로 내려오면 매수(매도는 반대)
3.청산/손절
-청산:
10틱수익시 1차 청산
20틱수익시 2차 청산
-손절:
수익이 10틱 미만일때 -30틱에서 손절
-본절:
1차 청산후 진입가 이하로 내려가려할때 진입가에서 청산
4.매매종료
매매시간 이내에(16시 ~ 04시까지) 현재 포지션이 종료된 상태에서 총합계 수익이 50틱이상 이면 당일 매매종료하고 현재 캔들의 고점 위에 당일 총합계 수익 표시 하고 동시에 a.wav 파일 실행
수고하세요^^
답변 1
예스스탁 예스스탁 답변
2017-11-29 16:11:50
안녕하세요
예스스탁입니다.
썸머타입여부는 알수 없습니다.
Input : 당일수익틱수(50);
Var : N1(0),dayPl(0),당일수익(0),Xcond(false);
var : Tcond(false);
당일수익 = PriceScale*당일수익틱수;
if stime == 170000 or (stime > 170000 and stime[1] < 170000) Then{
Tcond = true;
Xcond = false;
N1 = NetProfit;
}
if stime == 40000 or (stime > 40000 and stime[1] < 40000) Then
Tcond = false;
var1 = ma(C,20);
daypl = NetProfit-N1;
if TotalTrades > TotalTrades[1] and
(IsExitName("dbp",1) == true or IsExitName("dsp",1) == true) then{
Xcond = true;
Text_New(sdate,stime,H,NumToStr(daypl,2));
PlaySound("a.wav");
}
if Tcond == true and Xcond == false then{
if var1 > var1[1] and CrossDown(c,var1) Then
buy("b",OnClose,def,2);
if var1 < var1[1] and CrossUp(c,var1) Then
sell("s",OnClose,def,2);
if MarketPosition == 1 then{
ExitLong("bp1",AtLimit,EntryPrice+PriceScale*10,"",1,1);
ExitLong("bp2",AtLimit,EntryPrice+PriceScale*20);
if CurrentContracts < MaxContracts Then
ExitLong("bl1",AtStop,EntryPrice,"",1,1);
Else
ExitLong("bl2",AtStop,EntryPrice-PriceScale*30);
}
if MarketPosition == -1 then{
ExitShort("sp1",AtLimit,EntryPrice-PriceScale*10,"",1,1);
ExitShort("sp2",AtLimit,EntryPrice-PriceScale*20);
if CurrentContracts < MaxContracts Then
ExitShort("sl1",AtStop,EntryPrice,"",1,1);
Else
ExitShort("sl2",AtStop,EntryPrice+PriceScale*30);
}
if MarketPosition == 1 then{
ExitLong("dbp",atlimit,EntryPrice+((당일수익-daypl)/CurrentContracts));
}
if MarketPosition == -1 then{
ExitShort("dsp",atlimit,EntryPrice-((당일수익-daypl)/CurrentContracts));
}
}
즐거운 하루되세요
> 웹피 님이 쓴 글입니다.
> 제목 : 문의드립니다.
> 날씨가 많이 추워졌습니다. 감기조심하시구요.
아래와 같은 수식을 부탁드립니다.
1.매매시간
17시 ~ 04시까지 매매후 종료(섬머타임때는 16시 ~ 03시까지)
2.진입조건(2계약 진입)
매수 : 20일선 우상향 하고 캔들이 20일선 아래로 내려오면 매수(매도는 반대)
3.청산/손절
-청산:
10틱수익시 1차 청산
20틱수익시 2차 청산
-손절:
수익이 10틱 미만일때 -30틱에서 손절
-본절:
1차 청산후 진입가 이하로 내려가려할때 진입가에서 청산
4.매매종료
매매시간 이내에(16시 ~ 04시까지) 현재 포지션이 종료된 상태에서 총합계 수익이 50틱이상 이면 당일 매매종료하고 현재 캔들의 고점 위에 당일 총합계 수익 표시 하고 동시에 a.wav 파일 실행
수고하세요^^