커뮤니티
문의 드립니다.
2017-11-20 11:14:51
113
글번호 114323
틱90 차트에서,
30분봉의 일목 기준선, 전환선을 표현하고싶네요..
부탁드립니다..
답변 1
예스스탁 예스스탁 답변
2017-11-21 12:48:30
안녕하세요
예스스탁입니다.
input : 타분봉(30),전환선기간(9),기준선기간(26),선행스팬2기간(52);
var : TF(0);
var : cnt(0),H1(0),L1(0),H11(0),L11(0),H2(0),L2(0),H22(0),L22(0),H3(0),L3(0);
var : 전환선(0),기준선(0),선행스팬1(0),선행스팬2(0);
Array : HH[100](0),LL[100](0);
TF = TimeToMinutes(stime)%타분봉;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF < TF[1]) Then{
HH[0] = H;
LL[0] = L;
for cnt = 1 to 99{
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
}
}
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
if HH[선행스팬2기간+25] > 0 and LL[선행스팬2기간+25] > 0 then{
H1 = HH[0];
L1 = LL[0];
H11 = HH[25];
L11 = LL[25];
H2 = HH[0];
L2 = LL[0];
H22 = HH[25];
L22 = LL[25];
H3 = HH[25];
L3 = LL[25];
for cnt = 0 to 선행스팬2기간-1{
if cnt < 전환선기간 Then{
if HH[cnt] > H1 Then
H1 = HH[cnt];
if LL[cnt] < L1 Then
L1 = LL[cnt];
if HH[cnt+25] > H11 Then
H11 = HH[cnt+25];
if LL[cnt+25] < L11 Then
L11 = LL[cnt+25];
}
if cnt < 기준선기간 Then{
if HH[cnt] > H2 Then
H2 = HH[cnt];
if LL[cnt] < L2 Then
L2 = LL[cnt];
if HH[cnt+25] > H22 Then
H22 = HH[cnt+25];
if LL[cnt+25] < L22 Then
L22 = LL[cnt+25];
}
if HH[cnt+25] > H3 Then
H3 = HH[cnt+25];
if LL[cnt+25] < L3 Then
L3 = LL[cnt+25];
}
전환선 = (H1 + L1)/2;
기준선 = (H2 + L2)/2;
선행스팬1 = ((H11+L11)/2 + (H22+L22)/2) / 2 ;
선행스팬2 = (H3+L3) / 2;
plot1(전환선);
plot2(기준선);
}
즐거운 하루되세요
> 해월정 님이 쓴 글입니다.
> 제목 : 문의 드립니다.
> 틱90 차트에서,
30분봉의 일목 기준선, 전환선을 표현하고싶네요..
부탁드립니다..
다음글