커뮤니티
54939관련입니다.
2017-09-22 22:31:48
166
글번호 113023
-항상 친절한 답변 감사드립니다.
-54939에서 부탁드린 내용은 분봉의 볼밴이 아니고 일봉의 볼밴을 분봉차트에 표시하는 지표식이니 다시 한번더 부탁드립니다.
답변 1
예스스탁 예스스탁 답변
2017-09-25 14:26:31
안녕하세요
예스스탁입니다.
1
input : Period(20),Dv(2);
var : sum(0),cnt(0),mav(0),SumSqrt(0),Stdv(0);
var : BBup(0),BBdn(0),Counter(0);
If DayClose(Period) > 0 Then {
#일봉 이동평균 계산
sum = 0;
for cnt = 0 to Period-1{
sum = sum + DayClose(cnt);
}
mav = sum/Period;
#표준편차 계산
SumSqrt = 0;
For Counter = 0 To Period - 1 {
SumSqrt = SumSqrt + (DayClose(Counter) - mav)^2;
}
Stdv = SquareRoot(SumSqrt / Period);
# 일봉 볼린져밴드 계산
BBup = mav + (Dv * Stdv);
BBdn = mav - (Dv * Stdv);
plot1(BBup ,"상단");
plot2(mav,"중단");
plot3(BBdn,"하단");
}
2
# 분봉에서 일봉 볼린져밴드 계산 시작
input : Period(20),Dv(2);
var : sum(0,data2),cnt(0,data2),mav(0,data2),SumSqrt(0,data2),Stdv(0,data2);
var : BBup(0,data2),BBdn(0,data2);
Array : C2[100](0);
if data2(bdate != bdate[1]) then{
for cnt = 1 to 99{
C2[cnt] = C2[cnt-1][1];
}
}
C2[0] = data2(c);
If C2[Period] > 0 Then {
sum = 0;
for cnt = 0 to Period-1{
sum = sum + C2[cnt];
}
mav = sum/Period;
SumSqrt = 0;
For cnt = 0 To Period - 1 {
SumSqrt = SumSqrt + (C2[cnt] - mav)^2;
}
Stdv = SquareRoot(SumSqrt / Period);
# 일봉 볼린져밴드 계산
BBup = mav + (Dv * Stdv);
BBdn = mav - (Dv * Stdv);
plot1(BBup ,"상단");
plot2(mav,"중단");
plot3(BBdn,"하단");
}
즐거운 하루되세요
> 예시 님이 쓴 글입니다.
> 제목 : 54939관련입니다.
> -항상 친절한 답변 감사드립니다.
-54939에서 부탁드린 내용은 분봉의 볼밴이 아니고 일봉의 볼밴을 분봉차트에 표시하는 지표식이니 다시 한번더 부탁드립니다.