커뮤니티
매매식 부탁합니다.
2017-06-09 11:44:14
140
글번호 110283
주식시스템매매식을 만들고자 합니다.
매수식(열종목에 각 계좌평가금액의 10%를 매수하는식)
30분봉에서 정배열(5>20>60>120>240)에서 계좌평가금액의 10% 매수
단, 참조데이타1 동일종목 일봉 20ma>60ma, 참조데이타2, 동일종목 주봉 5ma>20ma 일 경우
매도식
30분봉에서 최근20개봉 최고가 대비 5% 하락시 매도
목표수익률 20% 달성시 매도
답변 1
예스스탁 예스스탁 답변
2017-06-09 13:33:55
안녕하세요
예스스탁입니다.
예스랭귀지 수식은 차트에 적용되어
차트 기본종목에만 신호가 발생하고 주문이 집행되니다
거래를 원하는 차트를 10개 만들고
각각 적용하셔야 합니다.
var : MM(0),vol(0);
var : mav11(0,data1),mav12(0,data1),mav13(0,data1),mav14(0,data1),mav15(0,data1);
var : mav21(0,data2),mav22(0,data2);
var : mav31(0,data3),mav32(0,data3);
MM = GetUnclearedDeposits("1000-0120-31");//<-적용계좌번호를 지정해 주셔야 합니다.
vol = Floor((MM*0.1)/C);
mav11 = data1(ma(c,5));
mav12 = data1(ma(c,20));
mav13 = data1(ma(c,60));
mav14 = data1(ma(c,120));
mav15 = data1(ma(c,240));
mav21 = data2(ma(C,20));
mav22 = data2(ma(C,60));
mav31 = data3(ma(C,5));
mav32 = data3(ma(C,20));
if mav11 > mav12 and mav12 > mav13 and mav13 > mav14 and mav14 > mav15 and
mav21 > mav22 and
mav31 > mav32 Then{
if MM > 0 Then
buy("b1",OnClose,def,vol);
Else
buy("b2",OnClose,def,1);//과거봉
}
if MarketPosition == 1 and data1(C<= highest(H,20)*0.95) Then
exitlong("bx");
SetStopProfittarget(20,PercentStop);
즐거운 하루되세요
> 후포 님이 쓴 글입니다.
> 제목 : 매매식 부탁합니다.
> 주식시스템매매식을 만들고자 합니다.
매수식(열종목에 각 계좌평가금액의 10%를 매수하는식)
30분봉에서 정배열(5>20>60>120>240)에서 계좌평가금액의 10% 매수
단, 참조데이타1 동일종목 일봉 20ma>60ma, 참조데이타2, 동일종목 주봉 5ma>20ma 일 경우
매도식
30분봉에서 최근20개봉 최고가 대비 5% 하락시 매도
목표수익률 20% 달성시 매도