커뮤니티
사용자 지표 문의입니다.
2017-06-07 21:10:07
221
글번호 110229
첨부 이미지
그림1
항상 고생하시는 전문가님 감사합니다.ㅎㅎ..
지표식 궁금해서 글 남깁니다.
1. 이전에 한번 남겼었는데..각 지표들이(전일고가 등등) Y축 값이 나오는게 아니라 그 지표가 끝나는 지점에서 지정한 지표의 이름이 나왔으면 좋겠어요 예시를 첨부파일로 올립니다.
2. 제가 원하는 수식을 만들어서 차트에다가 나오게 할 수 있나요? 예를들면 30일간의 고가-저가를 구해서 오늘의 고가-저가를 구해 나눈 비율과 같은 것들이요
3. 라운드 값 수평선으로 표시하고 싶은데 알려주신데로 햇더니 봉에 따라서 위로갔다 아래로갔다 하네요. 라운드 값에다가 점선으로 일직선으로 수평선으로 긋고 싶어요 오일은 50.00, 51.00마다 금은 1290.0, 1280.0 마다 엔은 0.91000, 0.92000 마다, 유로는 1.12000, 1.11000 마다, 호주달러는 0.75000, 0.74000 마다, 파운드는 1.2900, 1.2800마다 수평선 일직선으로 차트에 그어지게 하고싶어요.
4.30일간중 최고가, 최저가를 수평선으로 나타내고 싶어요.
미리 감사의 말씀 드립니다.
- 1. 110770_캡처1.PNG (0.01 MB)
답변 1
예스스탁 예스스탁 답변
2017-06-08 10:41:15
안녕하세요
예스스탁입니다.
1.
Y축에 표시는 가능하지 않고
차트의 마지막 완성봉에 텍스트함수로 출력은 가능합니다.
아래 내용 참고하시기 바랍니다.
var : tx1(0);
plot1(DayHigh(1),"전일고가");
#새로운 완성봉이 생기면 기존텍스트 출력삭제
Text_Delete(tx1);
#차트 마지막완성봉의 전일고가 위치에 "전일고가" 텍스트로 변경해 출력
tx1 = Text_New(sdate,stime,dayhigh(1),"전일고가");
2
input : n(30);
var : HH(0),LL(0),cnt(0),tx1(0);
HH = dayhigh(0);
LL = daylow(0);
for cnt = 0 to N-1{
if dayhigh(cnt) > HH Then
HH = dayhigh(cnt);
if DayLow(cnt) < LL Then
LL = DayLow(cnt);
}
var1 = (dayhigh(0)-daylow(0))/(HH-LL)*100;
#새로운 완성봉이 생기면 기존텍스트 출력삭제
Text_Delete(tx1);
#차트 마지막완성봉의 고가+2틱위에 var1을 텍스트로 변경해 출력
tx1 = Text_New(sdate,stime,H+PriceScale*2,NumToStr(var1,2));
3
해당 부분은 사용자분이 종목에 맞게 선을 출력하는 간격의 틱수를 지정해서 적용하셔야 합니다.
수식에서 종목에 맞게 처리해 드릴수 없습니다.
예를 들어 오일은 1포인트 간격이므로 100틱, 금은 10포이트 간격이므로 100틱,
유로는 0.01단위이므로 1000틱입니다.
input : 틱수(100);
Array : upLine[20](0),dnLine[20](0);
var : cnt(0),mdline(0),간격(0);
간격 = PriceScale*틱수;
if bdate != bdate[1] then{
var1 = Floor(O/간격);
var2 = var1*간격;
TL_Delete(mdLine);
mdLine = TL_New(sdate[1],stime[1],var2,sdate,stime,var2);
TL_SetExtLeft(mdLine,true);
TL_SetExtRight(mdLine,true);
for cnt = 1 to 19{
TL_Delete(upLine[cnt]);
TL_Delete(dnLine[cnt]);
upLine[cnt] = TL_New(sdate[1],stime[1],var2+간격*cnt,sdate,stime,var2+간격*cnt);
dnLine[cnt] = TL_New(sdate[1],stime[1],var2-간격*cnt,sdate,stime,var2-간격*cnt);
TL_SetExtLeft(upLine[cnt],true);
TL_SetExtLeft(dnLine[cnt],true);
TL_SetExtRight(upLine[cnt],true);
TL_SetExtRight(dnLine[cnt],true);
}
}
4
input : n(30);
var : HH(0),LL(0),cnt(0);
HH = dayhigh(0);
LL = daylow(0);
for cnt = 0 to N-1{
if dayhigh(cnt) > HH Then
HH = dayhigh(cnt);
if DayLow(cnt) < LL Then
LL = DayLow(cnt);
}
plot1(HH);
plot2(LL);
즐거운 하루되세요
> 추세추적자 님이 쓴 글입니다.
> 제목 : 사용자 지표 문의입니다.
> 항상 고생하시는 전문가님 감사합니다.ㅎㅎ..
지표식 궁금해서 글 남깁니다.
1. 이전에 한번 남겼었는데..각 지표들이(전일고가 등등) Y축 값이 나오는게 아니라 그 지표가 끝나는 지점에서 지정한 지표의 이름이 나왔으면 좋겠어요 예시를 첨부파일로 올립니다.
2. 제가 원하는 수식을 만들어서 차트에다가 나오게 할 수 있나요? 예를들면 30일간의 고가-저가를 구해서 오늘의 고가-저가를 구해 나눈 비율과 같은 것들이요
3. 라운드 값 수평선으로 표시하고 싶은데 알려주신데로 햇더니 봉에 따라서 위로갔다 아래로갔다 하네요. 라운드 값에다가 점선으로 일직선으로 수평선으로 긋고 싶어요 오일은 50.00, 51.00마다 금은 1290.0, 1280.0 마다 엔은 0.91000, 0.92000 마다, 유로는 1.12000, 1.11000 마다, 호주달러는 0.75000, 0.74000 마다, 파운드는 1.2900, 1.2800마다 수평선 일직선으로 차트에 그어지게 하고싶어요.
4.30일간중 최고가, 최저가를 수평선으로 나타내고 싶어요.
미리 감사의 말씀 드립니다.
다음글
이전글