커뮤니티
1분봉으로 60분봉, 120분봉 이평선 그리기
2017-05-26 11:56:10
118
글번호 109867
안녕하세요... 수고가 많으십니다.
몇가지 수식작성 부탁드립니다.
1. 1분봉으로 1시간봉의 5이평선, 20이평선, 60이평선을 그리는 수식 부탁 드립니다.
2. 1분봉으로 2시간봉의 5이평선, 20이평선, 60이평선을 그리는 수식 부탁 드립니다.
3. 1분봉으로 작성한 1시간봉의 5이평선의 전봉종가, 전전봉, 전전전봉종가를 확인하는
수식 부탁드립니다.
답변 1
예스스탁 예스스탁 답변
2017-05-26 13:26:16
안녕하세요
예스스탁입니다.
각 주기의 종가 및 이평이 배열변수로 처리되어 있습니다.
[0]이 현재, [1]이 전봉,[2]가 전전봉순입니다.
값이 0이 출력되거나 그려지지 않으면
해당값을 계산할 만큼 차트의 데이터가 충분하지 않다는 의미입니다.
수식은 차트의 데이터를 이용하므로 차트에 해당 값을 계산할 만큼 충분한 데이터가 없으면
타주기 계산이 불가능합니다.
input : P1(5),P2(20),P3(60),타분봉주기1(60),타분봉주기2(120);
var : cnt(0),S1(0),D1(0),TF1(0),TF2(0),TM(0);
var : sum11(0),sum12(0),sum13(0);
var : sum21(0),sum22(0),sum23(0);
Array : C1[100](0),C2[100](0);
Array : mav11[100](0),mav12[100](0),mav13[100](0);
Array : mav21[100](0),mav22[100](0),mav23[100](0);
if bdate != bdate[1] Then{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF1 = TM%타분봉주기1;
TF2 = TM%타분봉주기2;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF1 < TF1[1]) Then{
for cnt = 1 to 99{
C1[cnt] = C1[cnt-1][1];
mav11[cnt] = mav11[cnt-1][1];
mav12[cnt] = mav12[cnt-1][1];
mav13[cnt] = mav13[cnt-1][1];
}
}
C1[0] = C;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF2 < TF2[1]) Then{
for cnt = 1 to 99{
C2[cnt] = C2[cnt-1][1];
mav21[cnt] = mav21[cnt-1][1];
mav22[cnt] = mav22[cnt-1][1];
mav23[cnt] = mav23[cnt-1][1];
}
}
C2[0] = C;
if C1[P1] > 0 Then{
sum11 = 0;
for cnt = 0 to P1-1{
sum11 = sum11+C1[cnt];
}
mav11[0] = sum11/P1;
plot1(mav11[0],"타분봉1_P1이평");
}
if C1[P2] > 0 Then{
sum12 = 0;
for cnt = 0 to P2-1{
sum12 = sum12+C1[cnt];
}
mav12[0] = sum12/P2;
plot2(mav12[0],"타분봉1_P2이평");
}
if C1[P3] > 0 Then{
sum13 = 0;
for cnt = 0 to P3-1{
sum13 = sum13+C1[cnt];
}
mav13[0] = sum13/P3;
plot3(mav13[0],"타분봉1_P3이평");
}
if C2[P1] > 0 Then{
sum21 = 0;
for cnt = 0 to P1-1{
sum21 = sum21+C2[cnt];
}
mav21[0] = sum21/P1;
plot4(mav21[0],"타분봉2_P1이평");
}
if C2[P2] > 0 Then{
sum22 = 0;
for cnt = 0 to P2-1{
sum22 = sum22+C2[cnt];
}
mav22[0] = sum22/P2;
plot5(mav22[0],"타분봉2_P2이평");
}
if C2[P3] > 0 Then{
sum23 = 0;
for cnt = 0 to P3-1{
sum23 = sum23+C2[cnt];
}
mav23[0] = sum23/P3;
plot6(mav23[0],"타분봉2_P3이평");
}
}
즐거운 하루되세요
> 푸른파도1 님이 쓴 글입니다.
> 제목 : 1분봉으로 60분봉, 120분봉 이평선 그리기
> 안녕하세요... 수고가 많으십니다.
몇가지 수식작성 부탁드립니다.
1. 1분봉으로 1시간봉의 5이평선, 20이평선, 60이평선을 그리는 수식 부탁 드립니다.
2. 1분봉으로 2시간봉의 5이평선, 20이평선, 60이평선을 그리는 수식 부탁 드립니다.
3. 1분봉으로 작성한 1시간봉의 5이평선의 전봉종가, 전전봉, 전전전봉종가를 확인하는
수식 부탁드립니다.