커뮤니티
잘 부탁드립니다..
2017-05-23 06:03:20
85
글번호 109773
수고가 많으십니다.
Input : af(0.02), maxAF(0.2) ;
Var : value(0);
value = csar(af,maxAF);
# 매수/매도청산
If C > value Then
{
Buy();
}
# 매도/매수청산
If C < value Then
{
Sell();
}
위는 일반적인 파라볼락신호입니다. 이신호를 기준으로
1. 국선과 해선 둘로 나눠서 갭을 보정한 신호를 만들어주세요. 동일하게 적용되면 1개면 됩니다.
2. 매수(매도)진입후 0.4% 손절후 바로 동일방향으로 재진입신호가 안나오게 부탁합니다.
3. 매수(매도)진입후 0.4% 손절후 7개봉 이후에 5이평이 20이평 위에(아래에)있을때만 동일방향으로 재진입신호 뜨게 부탁합니다.
4. 매수(매도)진입후 0.5% 수익도달후 0.3% 밀리면 청산할수있게 부탁합니다.
이때도 바로 동일방향으로 재진입신호가 안나오게 부탁합니다.
5. 매수(매도)진입후 0.5% 수익도달후 0.3% 밀리면 청산한 시점에서 7개봉 이후에 5이평이 20이평 위에(아래에)있을때
동일방향으로 재진입신호 뜨게 부탁합니다.
미리 노고에 진심으로 감사드립니다.
답변 1
예스스탁 예스스탁 답변
2017-05-23 16:06:51
안녕하세요
예스스탁입니다.
국내/해외 공통식입니다.
Input: AF(0.02), AFMAX(0.2),P1(5),P2(20),손절(0.4),최소수익(0.5),수익감소(0.3);
Var : Direction(0), SAR_Value(Close), AF_Value(.02), HighValue(High), LowValue(Low), EP(0),GCSAR(0);
var : gap(0),sumgap(0),GO(0),GH(0),GL(0),GC(0),mav1(0),mav2(0);
if bdate != bdate[1] then {
gap = Open-Close[1];
sumGap = sumGap+gap;
}
GO = O - sumGap;
GH = H - sumGap;
GL = L - sumGap;
GC = C - sumGap;
if EP != 0 Then
{
if Direction == 1 then
{
EP = HighValue;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if GH > HighValue then
{
HighValue = GH;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
if Close < SAR_Value then
{
Direction = -1;
SAR_Value = EP;
AF_Value = 0;
EP = 0;
LowValue = Gl;
}
}
else
{
EP = LowValue;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if GL < LowValue then
{
LowValue = GL;
AF_Value = AF_Value + Af;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
if GC > SAR_Value then
{
Direction = 1;
SAR_Value = EP;
AF_Value = 0;
EP = 0;
HighValue = GH;
}
}
GCSar = SAR_Value;
}
else
{
if SAR_Value != 0 && EP == 0 then
{
if Direction == 1 then
{
EP = HighValue;
AF_Value = AF;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if GH > HighValue then
{
HighValue = GH;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
}
else
{
EP = LowValue;
AF_Value = Af;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if GL < LowValue then
{
LowValue = GL;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
}
GCSar = SAR_Value;
}
else
{
if Direction == 0 then
{
if GC > GC[1] then Direction = 1;
else
if GC < GC[1] then Direction = -1;
}
else
{
if Direction == 1 then
{
if GC < GC[1] then
{
Direction = -1;
SAR_Value = HighValue;
GCSar = SAR_Value;
}
}
if Direction == -1 then
{
if GC > GC[1] then
{
Direction = 1;
SAR_Value = LowValue;
GCSar = SAR_Value;
}
}
}
LowValue = min(GL,LowValue);
HighValue = max(GH,HighValue);
}
}
mav1 = ma(C,P1);
mav2 = ma(C,P2);
If C > GCSar Then
{
if (MarketPosition == 0 and MarketPosition(1) != 1) or
(MarketPosition == 0 and MarketPosition(1) == 1 and BarsSinceExit(1) >= 7 and mav1 > mav2) or
(MarketPosition == -1) then
Buy("b");
}
If C < GCSar Then
{
if (MarketPosition == 0 and MarketPosition(1) != -1) or
(MarketPosition == 0 and MarketPosition(1) == -1 and BarsSinceExit(1) >= 7 and mav1 < mav2) or
(MarketPosition == 1) then
sell("s");
}
SetStopLoss(손절,PercentStop);
SetStopTrailing(수익감소,최소수익,PercentStop,1);
즐거운 하루되세요
> 카르마다 님이 쓴 글입니다.
> 제목 : 잘 부탁드립니다..
> 수고가 많으십니다.
Input : af(0.02), maxAF(0.2) ;
Var : value(0);
value = csar(af,maxAF);
# 매수/매도청산
If C > value Then
{
Buy();
}
# 매도/매수청산
If C < value Then
{
Sell();
}
위는 일반적인 파라볼락신호입니다. 이신호를 기준으로
1. 국선과 해선 둘로 나눠서 갭을 보정한 신호를 만들어주세요. 동일하게 적용되면 1개면 됩니다.
2. 매수(매도)진입후 0.4% 손절후 바로 동일방향으로 재진입신호가 안나오게 부탁합니다.
3. 매수(매도)진입후 0.4% 손절후 7개봉 이후에 5이평이 20이평 위에(아래에)있을때만 동일방향으로 재진입신호 뜨게 부탁합니다.
4. 매수(매도)진입후 0.5% 수익도달후 0.3% 밀리면 청산할수있게 부탁합니다.
이때도 바로 동일방향으로 재진입신호가 안나오게 부탁합니다.
5. 매수(매도)진입후 0.5% 수익도달후 0.3% 밀리면 청산한 시점에서 7개봉 이후에 5이평이 20이평 위에(아래에)있을때
동일방향으로 재진입신호 뜨게 부탁합니다.
미리 노고에 진심으로 감사드립니다.
다음글
이전글