커뮤니티
수식 부탁합니다.
2017-05-11 21:07:17
168
글번호 109480
첨부 이미지
그림1
안녕하세요
1. 해외선물거래에서 그림과 같이 dayopen을 기준으로 60분봉의 거래량의 합이 10000 이상 될 때까지 하나의 가상 봉으로 설정하고, 다음 봉부터 또 거래량의 합이 10000 이상일 때 까지 또 다른 가상봉을 형성하게 하며, 한 개의 봉의 거래량이 10000 이상인 것은 그대로 한 개의 가상 봉으로 인정하여 가상봉의 시가, 종가, 고가, 저가 를 OO, CC, HH, LL 로 설정한다.
2. 이 가상봉의 가격 이동평균선
3. 이 가상봉의 MACD
4. 이 가상봉의 볼린저 밴드를 표시하는 식 부탁 합니다.
그럼 수고 하세요
- 1. 거래량_이상_가격지표-2.jpg (0.07 MB)
답변 1
예스스탁 예스스탁 답변
2017-05-12 11:39:00
안녕하세요
예스스탁입니다.
1.
input : n(100000);
var : sum(0),cnt(0);
Array : OO[100](0),HH[100](0),LL[100](0),CC[100](0);
if Bdate != Bdate[1] or sum >= n Then{
sum = 0;
OO[0] = O;
HH[0] = H;
LL[0] = L;
for cnt = 1 to 99{
OO[cnt] = OO[cnt-1][1];
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
CC[cnt] = CC[cnt-1][1];
}
}
sum = sum+v;
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
CC[0] = C;
plot1(OO[0]);
plot2(HH[0]);
plot3(LL[0]);
plot4(CC[0]);
2
input : n(100000),P(20);
var : sum(0),cnt(0),vv(0),mav(0);
Array : OO[100](0),HH[100](0),LL[100](0),CC[100](0);
if Bdate != Bdate[1] or sum >= n Then{
sum = 0;
OO[0] = O;
HH[0] = H;
LL[0] = L;
for cnt = 1 to 99{
OO[cnt] = OO[cnt-1][1];
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
CC[cnt] = CC[cnt-1][1];
}
}
sum = sum+v;
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
CC[0] = C;
if CC[P] > 0 then{
vv = 0;
for cnt = 0 to P-1{
vv = vv+CC[cnt];
}
mav = vv/P;
plot1(mav);
}
3
input : n(100000), short(12),long(26),sig(9);
var : sum(0),idx(0),EP1(0),EP2(0),EP3(0);
var : PreJISU1(0),PreJISU2(0),PreMACDs(0);
var : JISU1(0),JISU2(0),MACDs(0),MACDv(0);
EP1 = 2/(short+1);
EP2 = 2/(Long+1);
EP3 = 2/(sig+1);
if Bdate != Bdate[1] or sum >= n Then{
sum = 0;
idx = idx + 1;
PreJISU1 = JISU1[1];
PreJISU2 = JISU2[1];
PreMACDs = MACDs[1];
}
sum = sum+v;
if idx <= 1 then{
JISU1 = C;
JISU2 = C;
}
Else{
JISU1 = C * EP1 + PreJISU1 * (1-EP1);
JISU2 = C * EP2 + PreJISU2 * (1-EP2);
}
MACDV = JISU1-JISU2;
MACDs = MACDV * EP3 + PreMACDs * (1-EP3);
plot1(MACDV);
plot2(MACDS);
PlotBaseLine1(0);
4
input : n(100000),P(20),dv(2);
var : sum(0),cnt(0),vv(0),mav(0),SumSqrt(0),Stdv(0);
Array : OO[100](0),HH[100](0),LL[100](0),CC[100](0);
if Bdate != Bdate[1] or sum >= n Then{
sum = 0;
OO[0] = O;
HH[0] = H;
LL[0] = L;
for cnt = 1 to 99{
OO[cnt] = OO[cnt-1][1];
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
CC[cnt] = CC[cnt-1][1];
}
}
sum = sum+v;
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
CC[0] = C;
if CC[P] > 0 then{
vv = 0;
for cnt = 0 to P-1{
vv = vv+CC[cnt];
}
mav = vv/P;
SumSqrt = 0;
For cnt = 0 To P - 1 {
SumSqrt = SumSqrt + (CC[cnt] - mav)^2;
}
Stdv = SquareRoot(SumSqrt / P);
plot1(mav);
plot2(mav+stdv*dv);
plot3(mav-stdv*dv);
}
즐거운 하루되세요
> 유아독존 님이 쓴 글입니다.
> 제목 : 수식 부탁합니다.
> 안녕하세요
1. 해외선물거래에서 그림과 같이 dayopen을 기준으로 60분봉의 거래량의 합이 10000 이상 될 때까지 하나의 가상 봉으로 설정하고, 다음 봉부터 또 거래량의 합이 10000 이상일 때 까지 또 다른 가상봉을 형성하게 하며, 한 개의 봉의 거래량이 10000 이상인 것은 그대로 한 개의 가상 봉으로 인정하여 가상봉의 시가, 종가, 고가, 저가 를 OO, CC, HH, LL 로 설정한다.
2. 이 가상봉의 가격 이동평균선
3. 이 가상봉의 MACD
4. 이 가상봉의 볼린저 밴드를 표시하는 식 부탁 합니다.
그럼 수고 하세요
다음글
이전글