커뮤니티
문의드립니다.
2017-03-28 11:14:30
118
글번호 108206
안녕하세요. 활기찬 한 주 되세요.
아래와 같이 당일과 지정시간에 발생한 총수익에 따라 매매종료를 하려고 합니다.
매수진입조건 : 기준선 위에서 MACD 골든크로스 하면 매수진입(매도는 반대)
1.당일 총수익이 +50틱 초과시 현재 캔들 위에 총수익 틱수를 출력하고 모든 포지션 청산후 매매종료를 하려면 수식이 어떻게 되는지 궁금합니다.
2.지정시간(16시 ~ 익일 01시 사이) 총수익이 +50틱 초과시 현재 캔들 위에 총수익 틱수를 출력하고 모든 포지션 청산후 매매종료를 하려면 수식이 어떻게 되는지 궁금합니다.
수고하세요 ^^
답변 1
예스스탁 예스스탁 답변
2017-03-28 13:28:36
안녕하세요
예스스탁입니다.
1
input : short(12),long(26),sig(9),당일수익틱수(50);
var : MACDV(0),MACDS(0),N1(0),Xcond(false),dayPL(0),당일수익(0),tx(0);
MACDV = MACD(short,long);
MACDS = ema(MACDV,sig);
if Bdate != Bdate[1] Then{
N1 = NetProfit;
Xcond = false;
}
dayPL = NetProfit-N1;
당일수익 = PriceScale*당일수익틱수;
if TotalTrades > TotalTrades[1] and (IsExitName("dbx",1) or IsExitName("dsx",1)) Then{
Xcond = true;
tx = Text_New(ExitDate(1),ExitTime(1),H[BarsSinceExit(1)]+PriceScale*3,"당일수익"+NumToStr(daypl/PriceScale,0)+"틱");
Text_SetStyle(tx,2,2);
}
if Xcond == false then{
if crossup(MACDV,MACDS) and MACDV > 0 Then
buy();
if CrossDown(MACDV,MACDS) and MACDV < 0 Then
sell();
}
if MarketPosition == 1 then
ExitLong("dbx",atlimit,EntryPrice+당일수익-daypl);
if MarketPosition == -1 then
ExitShort("dsx",atlimit,EntryPrice-당일수익+daypl);
2
input : short(12),long(26),sig(9),당일수익틱수(50),시작시간(160000),종료시간(010000);
var : MACDV(0),MACDS(0),N1(0),Xcond(false),dayPL(0),당일수익(0),tx(0),Tcond(false);
MACDV = MACD(short,long);
MACDS = ema(MACDV,sig);
if stime == 시작시간 or (stime > 시작시간 and stime[1] < 시작시간) Then{
N1 = NetProfit;
Xcond = false;
Tcond = true;
}
if stime == 종료시간 or (stime > 종료시간 and stime[1] < 종료시간) Then{
Tcond = false;
if MarketPosition == 1 Then
ExitLong("bx");
if MarketPosition == -1 Then
ExitShort("sx");
}
dayPL = NetProfit-N1;
당일수익 = PriceScale*당일수익틱수;
if TotalTrades > TotalTrades[1] and (IsExitName("dbx",1) or IsExitName("dsx",1)) Then{
Xcond = true;
tx = Text_New(ExitDate(1),ExitTime(1),H[BarsSinceExit(1)]+PriceScale*3,"당일수익"+NumToStr(daypl/PriceScale,0)+"틱");
Text_SetStyle(tx,2,2);
}
if Xcond == false and Tcond == true then{
if crossup(MACDV,MACDS) and MACDV > 0 Then
buy();
if CrossDown(MACDV,MACDS) and MACDV < 0 Then
sell();
}
if MarketPosition == 1 then
ExitLong("dbx",atlimit,EntryPrice+당일수익-daypl);
if MarketPosition == -1 then
ExitShort("dsx",atlimit,EntryPrice-당일수익+daypl);
즐거운 하루되세요
> 웹피 님이 쓴 글입니다.
> 제목 : 문의드립니다.
> 안녕하세요. 활기찬 한 주 되세요.
아래와 같이 당일과 지정시간에 발생한 총수익에 따라 매매종료를 하려고 합니다.
매수진입조건 : 기준선 위에서 MACD 골든크로스 하면 매수진입(매도는 반대)
1.당일 총수익이 +50틱 초과시 현재 캔들 위에 총수익 틱수를 출력하고 모든 포지션 청산후 매매종료를 하려면 수식이 어떻게 되는지 궁금합니다.
2.지정시간(16시 ~ 익일 01시 사이) 총수익이 +50틱 초과시 현재 캔들 위에 총수익 틱수를 출력하고 모든 포지션 청산후 매매종료를 하려면 수식이 어떻게 되는지 궁금합니다.
수고하세요 ^^