커뮤니티
문의드립니다
2017-03-27 03:12:07
129
글번호 108191
주식관련하여 문의드립니다
1.수식문의
주봉: 시가 고가 저가 월봉: 시가 고가 저가 년봉: 시가 를 부탁드립니다.
2.평균단가
일봉차트상에 주봉평균단가, 월봉평균단가,년봉평균단가 수식을 부탁드립니다
답변 1
예스스탁 예스스탁 답변
2017-03-27 15:11:21
안녕하세요
예스스탁입니다.
1.
input : N(0);
var : cnt(0);
Array : WO[50](0),WH[50](0),WL[50](0),WC[50](0);
Array : MO[50](0),MH[50](0),ML[50](0),MC[50](0);
Array : YO[50](0),YH[50](0),YL[50](0),YC[50](0);
#주간
if DayOfWeek(Bdate) < DayOfWeek(Bdate[1]) Then{
WO[0] = O;
WH[0] = H;
WL[0] = L;
for cnt = 1 to 49{
WO[cnt] = WO[cnt-1][1];
WH[cnt] = WH[cnt-1][1];
WL[cnt] = WL[cnt-1][1];
WC[cnt] = WC[cnt-1][1];
}
}
if H > WH[0] Then
WH[0] = H;
if L < WL[0] Then
WL[0] = L;
WC[0] = C;
#월간
if Bdate > Bdate[1]+30 Then{
MO[0] = O;
MH[0] = H;
ML[0] = L;
for cnt = 1 to 49{
MO[cnt] = MO[cnt-1][1];
MH[cnt] = MH[cnt-1][1];
ML[cnt] = ML[cnt-1][1];
MC[cnt] = MC[cnt-1][1];
}
}
if H > MH[0] Then
MH[0] = H;
if L < ML[0] Then
ML[0] = L;
MC[0] = C;
#연간
if Bdate > Bdate[1]+1000 Then{
YO[0] = O;
YH[0] = H;
YL[0] = L;
for cnt = 1 to 49{
YO[cnt] = YO[cnt-1][1];
YH[cnt] = YH[cnt-1][1];
YL[cnt] = YL[cnt-1][1];
YC[cnt] = YC[cnt-1][1];
}
}
if H > YH[0] Then
YH[0] = H;
if L < YL[0] Then
YL[0] = L;
YC[0] = C;
if WO[n] > 0 then{
plot1(WO[n],"n주전시가");
plot2(WH[n],"n주전고가");
plot3(WL[n],"n주전저가");
}
if MO[n] > 0 then{
plot4(MO[n],"n월전시가");
plot5(MH[n],"n월전고가");
plot6(ML[n],"n월전저가");
}
if YO[n] > 0 then{
plot7(YO[n],"n년전시가");
plot8(YH[n],"n년전고가");
plot9(YL[n],"n년전저가");
}
2
input : N(0);
var : cnt(0);
var : sumwc(0),sumwi(0),summc(0),summi(0),sumyc(0),sumyi(0);
Array : WC[50](0),MC[50](0),YC[50](0);
#주간
if DayOfWeek(Bdate) < DayOfWeek(Bdate[1]) Then{
sumwc = 0 ;
sumwi = 0 ;
for cnt = 1 to 49{
WC[cnt] = WC[cnt-1][1];
}
}
sumwc = sumwc+C;
sumwi = sumwi+1;
WC[0] = sumwc/sumwi;
#월간
if Bdate > Bdate[1]+30 Then{
summc = 0 ;
summi = 0 ;
for cnt = 1 to 49{
MC[cnt] = MC[cnt-1][1];
}
}
summc = summc+C;
summi = summi+1;
MC[0] = summc/summi;
#연간
if Bdate > Bdate[1]+1000 Then{
sumyc = 0 ;
sumyi = 0 ;
for cnt = 1 to 49{
YC[cnt] = YC[cnt-1][1];
}
}
sumyc = sumyc+C;
sumyi = sumyi+1;
YC[0] = sumyc/sumyi;
if WC[n] > 0 then{
plot1(WC[n],"n주전평균가");
}
if MC[n] > 0 then{
plot2(MC[n],"n월전평균가");
}
if YC[n] > 0 then{
plot3(YC[n],"n년전평균가");
}
즐거운 하루되세요
> 럭키잭팟 님이 쓴 글입니다.
> 제목 : 문의드립니다
> 주식관련하여 문의드립니다
1.수식문의
주봉: 시가 고가 저가 월봉: 시가 고가 저가 년봉: 시가 를 부탁드립니다.
2.평균단가
일봉차트상에 주봉평균단가, 월봉평균단가,년봉평균단가 수식을 부탁드립니다