커뮤니티
추가질문입니다.
2017-03-06 18:15:56
123
글번호 107509
NO. 52243 과 관련입니다
당해지표식을 시스템식으로 변형하여 주시면 감사 하겠습니다.
* Plot1에 할당 된
(꺾은선) 과 (Iff(방향 == 상승,기준고,기준저))의 할당값을 모르겠습니다.
답변 1
예스스탁 예스스탁 답변
2017-03-06 18:48:41
안녕하세요
예스스탁입니다.
Input:상승전환가격(1),하락전환가격(1);
Var:j(0),꺾은선(0),방향(0),상승(100),하락(-100),
기준고(0),기준저(0),기준고Bar(0),기준저Bar(0);
Array:고[20](0),저[20](0),고Bar[20](0),저Bar[20](0);
#==========================================#
# 전고점,전저점 index 증가
#==========================================#
For j = 1 To 19
{
고Bar[j] = 고Bar[j] + 1;
저Bar[j] = 저Bar[j] + 1;
}
#==========================================#
# 최근 고,저 갱신
#==========================================#
If 기준고 <= C || 기준고 == 0 || IsNaN(기준고) == True Then
{
기준고 = C;
기준고Bar = 0;
}
Else
기준고Bar = 기준고Bar + 1;
If 기준저 >= C || 기준저 == 0 || IsNaN(기준저) == True Then
{
기준저 = C;
기준저Bar = 0;
}
Else
기준저Bar = 기준저Bar + 1;
#==========================================#
# 추세방향 결정
#==========================================#
If 기준저[1] + 상승전환가격 > C[1] && 기준저[1] + 상승전환가격 <= C Then 방향 = 상승;
If 기준고[1] - 하락전환가격 < C[1] && 기준고[1] - 하락전환가격 >= C Then 방향 = 하락;
#==========================================#
# 추세변화에 따른 변곡점 처리
#==========================================#
If 방향[1] == 하락 && 방향 == 상승 Then
{
For j = 18 DownTo 1
{
저[j+1] = 저[j];
저Bar[j+1] = 저Bar[j];
}
저[1] = 기준저;
저Bar[1] = 기준저Bar;
꺾은선 = 기준저;
기준저 = C;
기준저Bar = 0;
기준고 = C;
기준고Bar = 0;
}
Else If 방향[1] == 상승 && 방향 == 하락 Then
{
For j = 18 DownTo 1
{
고[j+1] = 고[j];
고Bar[j+1] = 고Bar[j];
}
고[1] = 기준고;
고Bar[1] = 기준고Bar;
꺾은선 = 기준고;
기준고 = C;
기준고Bar = 0;
기준저 = C;
기준저Bar = 0;
}
Else If 방향[1] == 하락 && 방향 == 하락 Then
{
If 기준고[1] - 하락전환가격 <= C[1] &&
기준고[1] - 하락전환가격 > C &&
고[1] < 기준고 Then
{
고[1] = 기준고;
고Bar[1] = 기준고Bar;
꺾은선 = 기준고;
기준고 = C;
기준고Bar = 0;
}
}
Else If 방향[1] == 상승 && 방향 == 상승 Then
{
If 기준저[1] + 상승전환가격 >= C[1] &&
기준저[1] + 상승전환가격 < C &&
저[1] > 기준저 Then
{
저[1] = 기준저;
저Bar[1] = 기준저Bar;
꺾은선 = 기준저;
기준저 = C;
기준저Bar = 0;
}
}
#==========================================#
# 지표식 출력
#==========================================#
If 꺾은선[1] != 꺾은선 Then {
if 꺾은선[1] < 꺾은선 Then
sell();
Else
buy();
}
즐거운 하루되세요.
> 너무조아 님이 쓴 글입니다.
> 제목 : 추가질문입니다.
> NO. 52243 과 관련입니다
당해지표식을 시스템식으로 변형하여 주시면 감사 하겠습니다.
* Plot1에 할당 된
(꺾은선) 과 (Iff(방향 == 상승,기준고,기준저))의 할당값을 모르겠습니다.