커뮤니티
수식작성문의드립니다.
2017-01-20 19:28:44
127
글번호 106160
수식문의드립니다.
당일 중심선을 기준으로 시가와종가가 모두 돌파 시
3계약 매수 (10틱익절, 20틱익절, 30틱익절)
당일 중심선을 기준으로 시가와 종가가 모두 하락돌파 시 기존 보유한 계약 있으면
모두 청산하고 매도로 3계약 스위칭 (10틱익절, 20틱익절, 30틱익절)
계속반복
당일 50틱 수익시 당일매매 종료
감사합니다.
답변 1
예스스탁 예스스탁 답변
2017-01-23 12:43:48
안녕하세요
예스스탁입니다.
input : 당일수익틱수(50);
var : 당일수익(0),Xcond(false),N1(0),dayPL(0);
당일수익 = PriceScale*당일수익틱수;
if Bdate != Bdate[1] Then{
Xcond = false;
N1 = NetProfit;
}
if TotalTrades > TotalTrades[1] and (IsExitName("bpx",1) == true or IsExitName("spx",1) == true) Then
Xcond = true;
daypl = NetProfit-N1;
var1 = (dayhigh+daylow)/2;
var2 = max(c,o);
var3 = min(c,o);
if crossup(var2,var1) and Xcond == false Then
buy("b",OnClose,def,3);
if CrossDown(var3,var1) and Xcond == false Then
sell("s",OnClose,def,3);
if MarketPosition == 1 Then{
ExitLong("bp1",atlimit,EntryPrice+PriceScale*10,"",1,1);
ExitLong("bp2",atlimit,EntryPrice+PriceScale*20,"",1,1);
ExitLong("bp3",atlimit,EntryPrice+PriceScale*30,"",1,1);
ExitLong("bpx",atlimit,EntryPrice+당일수익-daypl);
}
if MarketPosition == -1 Then{
ExitShort("sp1",atlimit,EntryPrice-PriceScale*10,"",1,1);
ExitShort("sp2",atlimit,EntryPrice-PriceScale*20,"",1,1);
ExitShort("sp3",atlimit,EntryPrice-PriceScale*30,"",1,1);
ExitShort("spx",atlimit,EntryPrice-당일수익+daypl);
}
즐거운 하루되세요
> 태양으로 님이 쓴 글입니다.
> 제목 : 수식작성문의드립니다.
> 수식문의드립니다.
당일 중심선을 기준으로 시가와종가가 모두 돌파 시
3계약 매수 (10틱익절, 20틱익절, 30틱익절)
당일 중심선을 기준으로 시가와 종가가 모두 하락돌파 시 기존 보유한 계약 있으면
모두 청산하고 매도로 3계약 스위칭 (10틱익절, 20틱익절, 30틱익절)
계속반복
당일 50틱 수익시 당일매매 종료
감사합니다.