커뮤니티
최고값 최저값 출력하는법
2017-01-12 08:49:44
115
글번호 105810
안녕하세요.
정해진 시간안의 최고가와 저가의 값을 출력하고싶은데 어떻게 해야 하나요?
또한 정해진 시간까지의 TR을 나타내게 할려면 어떻게 해야하나요?
1) 즉,
오전 9시부터 오전 10시까지중에서 최고가와 최저가를 지표로 나타내게 할려면 어떻게 짜야 하나요?
2) 오전9시부터 오전 10시까지의 TR을 나타내게 할려면요?
답변 1
예스스탁 예스스탁 답변
2017-01-12 11:18:47
안녕하세요
예스스탁입니다.
1.
input : 시작시간(90000),끝시간(100000);
var : HH(0),LL(0),Tcond(false);
if stime == 시작시간 or (stime > 시작시간 and stime[1] < 시작시간) Then{
HH = H;
LL = L;
Tcond = true;
}
if stime == 끝시간 or (stime > 끝시간 and stime[1] < 끝시간) Then{
Tcond = false;
}
if Tcond == true then{
if H > HH Then
HH = H;
if L < LL Then
LL = L;
}
plot1(HH);
plot2(LL);
2
input : 시작시간(90000),끝시간(100000);
var : HH(0),LL(0),Tcond(false),PreC(0),TH(0),TL(0),TR(0);
if stime == 시작시간 or (stime > 시작시간 and stime[1] < 시작시간) Then{
HH = H;
LL = L;
Tcond = true;
PreC = C[1];
}
if stime == 끝시간 or (stime > 끝시간 and stime[1] < 끝시간) Then{
Tcond = false;
}
if Tcond == true then{
if H > HH Then
HH = H;
if L < LL Then
LL = L;
If PreC > HH then
TH = PreC;
else
TH = HH;
If PreC < LL then
TL = PreC;
else
TL = LL;
TR = TH-TL;
}
plot1(TR);
즐거운 하루되세요
> 포리버스 님이 쓴 글입니다.
> 제목 : 최고값 최저값 출력하는법
> 안녕하세요.
정해진 시간안의 최고가와 저가의 값을 출력하고싶은데 어떻게 해야 하나요?
또한 정해진 시간까지의 TR을 나타내게 할려면 어떻게 해야하나요?
1) 즉,
오전 9시부터 오전 10시까지중에서 최고가와 최저가를 지표로 나타내게 할려면 어떻게 짜야 하나요?
2) 오전9시부터 오전 10시까지의 TR을 나타내게 할려면요?