커뮤니티
문의 드립니다.
2017-01-03 10:14:17
154
글번호 105523
연결선물지수 1분봉 챠트 사용중입니다.
일간 변할때 이평선의 왜곡을 피하고자 갭보정 챠트를 사용하고 있습니다.
사용하는 이평선은.... 20 35 60 120 지수 이평선입니다.
갭조정 챠트를 사용하지 않고 일반 챠트를 사용하면서,
일간 이평선의 왜곡을 피하는 방법은 없을까해서 문의 드립니다.
(당일 봉만 이용해서 이평선이 그려진다던지.... )
항상 건강하시고, 새해 복많이 받으세요.
답변 1
예스스탁 예스스탁 답변
2017-01-03 11:32:18
안녕하세요
예스스탁입니다.
1
아래는 당일봉만 사용해 그리는 지수이평식입니다.
당일봉만 사용해 그려도 갭을 피할수는 없습니다.
Input : P1(20),P2(35),P3(60),P4(120);
Var : Ep1(0), JISU1(0), PreJISU1(0);
Var : Ep2(0), JISU2(0), PreJISU2(0);
Var : Ep3(0), JISU3(0), PreJISU3(0);
Var : Ep4(0), JISU4(0), PreJISU4(0);
Ep1 = 2/(P1+1);
Ep2 = 2/(P2+1);
Ep3 = 2/(P3+1);
Ep4 = 2/(P4+1);
if Bdate != Bdate[1] Then{
JISU1 = C;
JISU2 = C;
JISU3 = C;
JISU4 = C;
}
else{
JISU1 = C * EP1 + JISU1 * (1-EP1);
JISU2 = C * EP2 + JISU2 * (1-EP2);
JISU3 = C * EP3 + JISU3 * (1-EP3);
JISU4 = C * EP4 + JISU4 * (1-EP4);
}
plot1(JiSu1);
plot2(Jisu2);
plot3(Jisu3);
plot4(Jisu4);
2
1번 식을 당일만 표시하고 하시면 아래와 같이 작성하시면 됩니다.
Input : P1(20),P2(35),P3(60),P4(120);
Var : Ep1(0), JISU1(0), PreJISU1(0);
Var : Ep2(0), JISU2(0), PreJISU2(0);
Var : Ep3(0), JISU3(0), PreJISU3(0);
Var : Ep4(0), JISU4(0), PreJISU4(0);
Ep1 = 2/(P1+1);
Ep2 = 2/(P2+1);
Ep3 = 2/(P3+1);
Ep4 = 2/(P4+1);
if Bdate != Bdate[1] Then{
JISU1 = C;
JISU2 = C;
JISU3 = C;
JISU4 = C;
}
else{
JISU1 = C * EP1 + JISU1 * (1-EP1);
JISU2 = C * EP2 + JISU2 * (1-EP2);
JISU3 = C * EP3 + JISU3 * (1-EP3);
JISU4 = C * EP4 + JISU4 * (1-EP4);
}
if CurrentDate == sdate then{
plot1(JiSu1);
plot2(Jisu2);
plot3(Jisu3);
plot4(Jisu4);
}
3
아래는 갭보정하지 않은 차트에서
수식으로 갭을 보정해 그리는 식입니다.
기본차트속성의 갭보정을 하면
당일 데이터를 고정한 상태에서 과거일로 가면서 보정하지면
수식은 과거로 가면서 계산을해서 반영하지는 못하므로]
차트상 첫봉부터 마지막으로 오면 갭을 누적해 보정된 종가를 계산해 사용하게 됩니다.
이평은 단절없이 보실수 있지만
차트의 값과는 괴리가 발생할수 있습니다.
이용에 참고하시기 바랍니다.
Input : P1(20),P2(35),P3(60),P4(120);
var : sumGap(0), gap(0),GC(0);
var : Gma1(0), Gma2(0), Gma3(0),Gma4(0);
if bdate != bdate[1] then { // 날짜가 변경되는 봉에서(분봉에서 첫번째 봉)
gap = Open-Close[1]; // 일간갭
sumGap = sumGap+gap; // 일간갭 누적
}
GC = C - sumGap; // 갭보정 종가
Gma1 = ema(GC,P1);
Gma2 = ema(GC,P2);
Gma3 = ema(GC,P3);
Gma4 = ema(GC,P4);
plot1(Gma1);
plot2(Gma2);
Plot3(Gma3);
Plot4(Gma4);
즐거운 하루되세요
> 묻어가는자 님이 쓴 글입니다.
> 제목 : 문의 드립니다.
> 연결선물지수 1분봉 챠트 사용중입니다.
일간 변할때 이평선의 왜곡을 피하고자 갭보정 챠트를 사용하고 있습니다.
사용하는 이평선은.... 20 35 60 120 지수 이평선입니다.
갭조정 챠트를 사용하지 않고 일반 챠트를 사용하면서,
일간 이평선의 왜곡을 피하는 방법은 없을까해서 문의 드립니다.
(당일 봉만 이용해서 이평선이 그려진다던지.... )
항상 건강하시고, 새해 복많이 받으세요.
이전글