커뮤니티
수식 요청
2016-11-08 15:50:59
79
글번호 103814
안녕하세요.
귀사에서 제공하는 파라볼릭 시스템 신호로 하기 조건 추가 부탁드립니다.(복합챠트 사용)
주간 ==> 야간장 / 야간장 ==> 주간장 넘어갈때 갭이 생기는 경우에 대한 질문입니다.
# 갭이 1피 이상 발생시 신규 신호 발생 금지
# 기존 신호가 손절시 바로 신호 발생 금지
# 2가지 조건 각각 요청(수치입력 및 수정 가능)
1) 10분이후 신규 신호 발생
2) 20캔들 이후 신규 신호 발생
항상 감사드립니다.
답변 1
예스스탁 예스스탁 답변
2016-11-09 08:44:08
안녕하세요
예스스탁입니다.
Input : af(0.02), maxAF(0.2),갭(1),손절틱수(10),대기분수(10),대기봉수(20);
Var : value(0),Gap(false),Xcond(false);
value = sar(af,maxAF);
var : S1(0),S2(0),TM(0),TF(0);
if Bdate != Bdate[1] Then{
S1 = TimeToMinutes(stime);
S2 = stime;
}
if S1 > 0 Then{
if Stime >= S2 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
}
if Bdate != Bdate[1] or (stime >= 180000 and stime[1] < 180000) Then{
Xcond = false;
if O >= C[1]+갭 or O <= C[1]-갭 then
Gap = true;
Else
Gap = False;
}
if TotalTrades > TotalTrades[1] and IsExitName("StopLoss",1) == true Then
Xcond = true;
if MarketPosition != 0 Then
Xcond = false;
If Gap == false and crossup(C,value) Then {
if Xcond == false Then
Buy("b");
if MarketPosition == 0 and Xcond == true and TM >= TM[BarsSinceExit(1)]+대기분수 Then
buy("b1");
if MarketPosition == 0 and Xcond == true and BarsSinceExit(1) >= 대기봉수 Then
buy("b2");
}
If Gap == false and CrossDown(C,value) Then {
if Xcond == false Then
Sell("s");
if MarketPosition == 0 and Xcond == true and TM >= TM[BarsSinceExit(1)]+대기분수 Then
sell("s1");
if MarketPosition == 0 and Xcond == true and BarsSinceExit(1) >= 대기봉수 Then
sell("s2");
}
SetStopLoss(PriceScale*손절틱수,PointStop);
즐거운 하루되세요
> 한국사람73 님이 쓴 글입니다.
> 제목 : 수식 요청
> 안녕하세요.
귀사에서 제공하는 파라볼릭 시스템 신호로 하기 조건 추가 부탁드립니다.(복합챠트 사용)
주간 ==> 야간장 / 야간장 ==> 주간장 넘어갈때 갭이 생기는 경우에 대한 질문입니다.
# 갭이 1피 이상 발생시 신규 신호 발생 금지
# 기존 신호가 손절시 바로 신호 발생 금지
# 2가지 조건 각각 요청(수치입력 및 수정 가능)
1) 10분이후 신규 신호 발생
2) 20캔들 이후 신규 신호 발생
항상 감사드립니다.