커뮤니티
수식으로 표현가능한지요
2016-09-20 13:15:26
120
글번호 102050
수고많으십니다.
1. 15분 50이평, 30분 50이평, 60분 50이평,
3개분봉에서 이평선 위에 2개가 있을때는 매수 대응
또는 3개가 모두 위에 있을때 매수대응으로 보고
진입은 5분봉 원하는 조건(보조지표)이 되었을때 가능한지요.
( 진입은 5분봉으로 하기 때문에 15분, 30분, 60분 이평선을 환산해서 5분봉 이평으로
기준을 하는것인지요)
2. 쌍봉, 쌍바닥은 봉 몇개 또는 시간개념으로 조건을 주어야 하는지요
3. 보조지표 4개를 사용할 때 4개 지표가 모두 충족될때 신호 발생.
수식으로 가능한지 궁금합니다.
답변 1
예스스탁 예스스탁 답변
2016-09-21 14:13:00
안녕하세요
예스스탁입니다.
1.
input : P(50);
var : cnt(0),TF1(0),TF2(0),TF3(0);
var : sum1(0),mav1(0),sum2(0),mav2(0),sum3(0),mav3(0);
var : upcount(0),dncount(0);
Array : C1[100](0),C2[100](0),C3[100](0);
TF1 = TimeToMinutes(stime)%15;
TF2 = TimeToMinutes(stime)%30;
TF3 = TimeToMinutes(stime)%60;
#15분 주기로 종가저장
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF1 < TF1[1]) then{
for cnt = 1 to 99{
C1[cnt] = C1[cnt-1][1];
}
}
C1[0] = C;
#30분 주기로 종가저장
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF2 < TF2[1]) then{
for cnt = 1 to 99{
C2[cnt] = C2[cnt-1][1];
}
}
C2[0] = C;
#60분 주기로 종가저장
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF3 < TF3[1]) then{
for cnt = 1 to 99{
C3[cnt] = C3[cnt-1][1];
}
}
C3[0] = C;
#15분봉 50이평선계산
if C1[P] > 0 Then{
sum1 = 0;
for cnt = 0 to P-1{
sum1 = sum1+C1[cnt];
}
mav1 = sum1/P;
}
#30분봉 50이평선계산
if C2[P] > 0 Then{
sum2 = 0;
for cnt = 0 to P-1{
sum2 = sum2+C2[cnt];
}
mav2 = sum2/P;
}
#60분봉 50이평선계산
if C3[P] > 0 Then{
sum3 = 0;
for cnt = 0 to P-1{
sum3 = sum3+C3[cnt];
}
mav3 = sum3/P;
}
#종가가 이평들보다 큰 횟수
upcount = 0;
if C > mav1 Then
upcount = upcount+1;
if C > mav2 Then
upcount = upcount+1;
if C > mav3 Then
upcount = upcount+1;
#종가가 이평들보다 작은 횟수
dncount = 0;
if C < mav1 Then
dncount = dncount+1;
if C < mav2 Then
dncount = dncount+1;
if C < mav3 Then
dncount = dncount+1;
#종가가 이평들중 최소 2개이상보다 크면 매수
if upcount >= 2 Then
buy();
#종가가 이평들중 최소 2개이상보다 작으면 매도
if dncount >= 2 Then
sell();
2
해당 부분은 선택사항입니다.
꼭 고점과 고점사이, 저점과 저점사이의 봉수나 시간을 지정할 필요는 없습니다.
다만 고점과 고점, 저점과 저점이 너무 멀리 있으면 의미가 없으므로
일반적으로는 몇봉이내등 봉수나 시간으로 지정하는 편입니다.
3
아래 내용 참고하시기 바랍니다.
var : mav1(0),mav2(0),MACDV(0),MACDS(0),stok(0),stod(0),DP(0),DM(0);
var : BuyCount(0),SellCount(0);
mav1 = ma(C,5);
mav2 = ma(C,20);
MACDV = MACD(12,26);
MACDS = ema(MACDV,9);
stok = StochasticsK(10,5);
stod = StochasticsD(10,5,5);
DP = Diplus(14);
DM = DiMinus(14);
BuyCount = 0;
if mav1 > mav2 Then
BuyCount = BuyCount+1;
if MACDV > MACDS Then
BuyCount = BuyCount+1;
if stok > Stod Then
BuyCount = BuyCount+1;
if DP > DM Then
BuyCount = BuyCount+1;
SellCount = 0;
if mav1 < mav2 Then
SellCount = SellCount+1;
if MACDV < MACDS Then
SellCount = SellCount+1;
if stok < Stod Then
SellCount = SellCount+1;
if DP < DM Then
SellCount = SellCount+1;
if BuyCount == 4 and BuyCount[1] != 4 Then
buy();
if SellCount == 4 and SellCount[1] != 4 Then
sell();
즐거운 하루되세요
> 매의눈 님이 쓴 글입니다.
> 제목 : 수식으로 표현가능한지요
> 수고많으십니다.
1. 15분 50이평, 30분 50이평, 60분 50이평,
3개분봉에서 이평선 위에 2개가 있을때는 매수 대응
또는 3개가 모두 위에 있을때 매수대응으로 보고
진입은 5분봉 원하는 조건(보조지표)이 되었을때 가능한지요.
( 진입은 5분봉으로 하기 때문에 15분, 30분, 60분 이평선을 환산해서 5분봉 이평으로
기준을 하는것인지요)
2. 쌍봉, 쌍바닥은 봉 몇개 또는 시간개념으로 조건을 주어야 하는지요
3. 보조지표 4개를 사용할 때 4개 지표가 모두 충족될때 신호 발생.
수식으로 가능한지 궁금합니다.
다음글
이전글