커뮤니티
참조 데이타 활용 수식 문의
2016-08-25 10:09:42
103
글번호 101337
안녕하세요, 아래와 같은 수식을 짜고 있는데 참조데이타 활용을 잘 안하여 봐서 어려움이 있습니다.
주 데이타 : 15분 봉
참조데이타 1 : 60분 봉
참조데이타 2 : 5분 봉
참조1이 볼린저 밴드 상단을 돌파하고,
참조 2가 볼린저 밴드 상단을 돌파하였을때,
주 데이타가 볼린저 밴드 상단을 돌파하였다면, 매수
간단하게 이렇게 구현하고자 한다면 어떻게 작성하면 될까요?
감사합니다.
답변 1
예스스탁 예스스탁 답변
2016-08-25 11:48:23
안녕하세요
예스스탁입니다.
input : P(20),dv(2);
var : BBup1(0,data1),BBdn1(0,data1),up2(0,data1),up3(0,data1);
var : BBup2(0,data2),BBdn2(0,data2);
var : BBup3(0,data3),BBdn3(0,data3);
#data1(주데이터) 볼밴
BBup1 = data1(BollBandUp(P,dv));
BBdn1 = data1(BollBandDown(P,dv));
#data2(주데이터) 볼밴
BBup2 = data2(BollBandUp(P,dv));
BBdn2 = data2(BollBandDown(P,dv));
#data3(주데이터) 볼밴
BBup3 = data3(BollBandUp(P,dv));
BBdn3 = data3(BollBandDown(P,dv));
#data2에서 상단돌파 시점의 data1의 봉번호 저장
#data1의 봉번호를 저장하는 이유는 동일 시계열에서 선후를 판단하기 위함입니다.
if data2(crossup(c,BBup2)) Then
up2 = data1(index);
#data3에서 상단돌파 시점의 data1의 봉번호 저장
if data3(Crossup(c,BBup3)) Then
up3 = data1(index);
if data1(crossup(c,BBup1)) and #현재 data1 상단돌파
data2(c > BBup2) and #data2 상단돌파상태
data3(C > BBup3) and #data3 상단돌파상태
up3 >= up2 Then #data3돌파가 data 돌파보다 같은 시점이거나 늦게 발생
buy();
즐거운 하루되세요
> 라면의비밀 님이 쓴 글입니다.
> 제목 : 참조 데이타 활용 수식 문의
> 안녕하세요, 아래와 같은 수식을 짜고 있는데 참조데이타 활용을 잘 안하여 봐서 어려움이 있습니다.
주 데이타 : 15분 봉
참조데이타 1 : 60분 봉
참조데이타 2 : 5분 봉
참조1이 볼린저 밴드 상단을 돌파하고,
참조 2가 볼린저 밴드 상단을 돌파하였을때,
주 데이타가 볼린저 밴드 상단을 돌파하였다면, 매수
간단하게 이렇게 구현하고자 한다면 어떻게 작성하면 될까요?
감사합니다.