커뮤니티
문의드립니다
2016-08-02 05:49:27
96
글번호 100612
48928번재문의드립니다
문의드린 답변감사드립니다 제가원하는것은 맛습니다 그런데 한가지 더 날마다 당일즉 오픈을기준으로 중심선이 나오도록다시한번 부탁드립니다 ~~항상감사드립니다
답변 1
예스스탁 예스스탁 답변
2016-08-02 14:07:08
안녕하세요
예스스탁입니다.
Input:기간(500),구간개수(10); //최대 20
Var:최대(0),최소(0),j(0),행번호(0),총거래량(0),가격대거래량(0),
시작번호(0),끝번호(0),bars(0);
Array:가격대[21](0),거래량[21](0),비율[21](0),Text[21](0),TL[21](0);
#----------------------------------------------------------------------------------#
# 가격대를 배열변수에 세팅한다.
#----------------------------------------------------------------------------------#
최대 = Highest(H,기간-1);
최소 = Lowest(L,기간-1);
Value1 = Round((최대-최소)/구간개수,0);
가격대[0] = 최대;
For 행번호 = 0 To 구간개수-1 {
가격대[행번호+1] = 가격대[행번호] - Value1;
거래량[행번호] = 0;
비율[행번호] = 0;
}
총거래량 = 0;
For j = 0 To 기간-2 {
총거래량 = 총거래량 + V[j];
#----------------------------------------------------------------------------------#
# 거래량을 걸쳐있는 가격대에 분배
#----------------------------------------------------------------------------------#
for 행번호 = 0 To 구간개수-1 {
if 가격대[행번호] >= H[j] and 가격대[행번호+1] < H[j] then 시작번호 = 행번호;
if 가격대[행번호] >= L[j] and 가격대[행번호+1] < L[j] then 끝번호 = 행번호;
}
가격대거래량 = V[j]/(끝번호-시작번호+1);
for 행번호 = 시작번호 To 끝번호 {
거래량[행번호] = 거래량[행번호] + 가격대거래량;
}
}
#----------------------------------------------------------------------------------#
# 비율 계산
#----------------------------------------------------------------------------------#
for 행번호 = 0 To 구간개수-1 {
비율[행번호] = 거래량[행번호] * 100 / 총거래량;
}
#----------------------------------------------------------------------------------#
# 지표출력
#----------------------------------------------------------------------------------#
bars = Floor(구간개수/2);
var : DD(0),TT(0),DD1(0),TT1(0),TL1(0),text1(0);
if bdate != bdate[1] Then{
DD = sdate;
TT = stime;
DD1 = DD[1];
TT1 = TT[1];
TL1 = TL_New(DD1,TT1,가격대[bars][1],sDate[1],sTime[1],가격대[bars][1]);
TL_SetSize(TL1,3);//추세선 굵기지정(0~8)
Text1 = Text_New(date[1], stime[1], (가격대[bars][1]+가격대[bars+1][1])/2,NumToStr(거래량[bars][1],0)
+" ("+NumToStr(비율[bars][1],2)+"%)("+NumToStr(가격대[bars+1][1],0)+" ~ "+NumToStr(가격대[bars][1],0)+")");
Text_SetStyle(Text1, 1, 2);
}
TL_Delete(TL[bars]);
TL[bars] = TL_New(DD,TT,가격대[bars],Date[0],sTime[0],가격대[bars]);
TL_SetSize(TL[bars],3);//추세선 굵기지정(0~8)
Text_Delete(Text[bars]);
Text[bars] = Text_New(date, stime, (가격대[bars]+가격대[bars+1])/2,NumToStr(거래량[bars],0)
+" ("+NumToStr(비율[bars],2)+"%)("+NumToStr(가격대[bars+1],0)+" ~ "+NumToStr(가격대[bars],0)+")");
Text_SetStyle(Text[bars], 1, 2);
즐거운 하루되세여
> 장군 님이 쓴 글입니다.
> 제목 : 문의드립니다
> 48928번재문의드립니다
문의드린 답변감사드립니다 제가원하는것은 맛습니다 그런데 한가지 더 날마다 당일즉 오픈을기준으로 중심선이 나오도록다시한번 부탁드립니다 ~~항상감사드립니다
다음글
이전글